From defrel and facts to core.logic.pldb

Question

Would appreciate any help on how this code should be changed with regards to the deprecation of defrel and facts and the move to pldb?

Here's the code:

(defrel parent x y)
(facts parent ’[[dave kaylen]
                [frank dave]])

(defn grandparent
    [x y]
    (fresh [z]
        (parent x z)
        (parent z y)))

;; In the REPL
user> (run* [q]
          (fresh [x y]
              (grandparent x y)
              (== q [x y])))
;; Result
([frank kaylen])

NielsK · Accepted Answer · 2014-05-22 20:27:39Z

11

(ns your.ns.here
  (:require [clojure.core.logic.pldb :as pldb]
            [clojure.core.logic :refer :all]))

(pldb/db-rel parent p1 p2)

(def facts
  (pldb/db
    [parent 'dave 'kaylen]
    [parent 'frank 'dave]))

(defn grandparent
  [x y]
  (fresh [z]
         (parent x z)
         (parent z y)))

(pldb/with-db facts
              (doall (run* [q]
                           (fresh [x y]
                                  (grandparent x y)
                                  (== q [x y])))))
=> ([frank kaylen])

See the pldb tests from core.logic source for more examples

edited May 22, 2014 at 20:27

answered May 22, 2014 at 20:22

NielsK

6,9561 gold badge25 silver badges46 bronze badges

Add a comment |

Collectives™ on Stack Overflow

From defrel and facts to core.logic.pldb

1 Answer 1

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

Your Answer

Sign up or log in

Post as a guest

Related