@echo off

rem ***** 設定箇所 *****

rem ↓ffmpeg.exeのパスを指定
set ffmpegdir=C:\Applications\ffmpeg\bin\ffmpeg.exe

rem ↓ffmpegでMP4に変換する際に元のTSファイルを削除するか
rem (0なら削除しない、1なら削除する)
set TSdelete=1


rem ***** 内部処理 *****

echo.
echo   ========================================================
echo                        Abema-DL  v2.0
:start
echo   ========================================================
echo.
echo     保存する動画または生放送のURLを入力してください：
echo     例：動画または生放送のURL：https://abema.tv/video/episode/25-43zr98hyeb55_s0_p1
echo.
set /P URL=":   動画または生放送のURL："
echo.
echo     保存する動画の画質を best・1080p・720p・480p・360p・240p・180p から選び、入力してください：
echo     例：保存する動画の画質：best （通常は best を推奨します）
echo.
set /P quality=":   保存する動画の画質："
echo.
echo     動画の保存先を入力してください：
echo     保存先のフォルダがない場合、自動で作成します。
echo     例：動画の保存先：D:\Anime\NEW_GAME\NEW_GAME_1-1.mp4
echo.
set /P file=":   動画の保存先："

call :filename "%file%"
exit /b 
:filename
set out=%~n1
set folder=%~dp1

echo.

rem echo     "%folder%%out%.ts"
echo     ダウンロードを開始します。
echo     生放送の場合、録画を止めたい時間になったら Ctrl + C を押して録画を中断させてください。
echo     その後、バッチ処理を終了しますか？と出たら n を入力し、続行してください。
echo.
set /P pause=":   続行するには何かキーを押してください："
echo.
echo   ========================================================

echo.
If not exist "%folder%" mkdir "%folder%"
Streamlink "%URL%" "%quality%" -o "%folder%%out%.ts"

if %errorlevel% neq 0 if %errorlevel% neq 130 (
  echo.
  echo   ========================================================
  echo.
  echo     ダウンロードに失敗しました… エラーコード："%errorlevel%"
  echo.
  echo     URLが正しいかどうか、正しく入力されているかどうか、確認してください。
)

if %errorlevel% equ 0 (
  "%ffmpegdir%" -i "%folder%%out%.ts" -c copy "%folder%%out%.mp4"
  if %TSdelete% equ 1 (
    del "%folder%%out%.ts"
  )
)
if %errorlevel% equ 130 (
  "%ffmpegdir%" -i "%folder%%out%.ts" -c copy "%folder%%out%.mp4"
  if %TSdelete% equ 1 (
    del "%folder%%out%.ts"
  )
)
echo.

echo   ========================================================
echo.
echo     ダウンロードを終了しました。
echo.
SET /P answer=":   他の動画や生放送もダウンロードしますか？(Y/N)："
echo.

if /i {%answer%}=={y} (goto :start)
if /i {%answer%}=={yes} (goto :start)
echo.

set /P pause=":   終了するには何かキーを押してください："