こんにちは、やきつかです。
Haskellで配列を使ってみたいなーと思っていて、Poisson方程式を数値計算してみたら40行だったので1人で感動しちゃたので残しておきます。
Haskellの表現力の強さを知ってもらえればうれしいです。

注意

とりあえず実装したかったので、処理速度とかは一切考慮してないです。
同じ理由で、精度も可視化していい感じになることを目指しています。
Haskell、数値計算とも初学者なので、間違いとかよりよい作法がありましたら教えていただけると大変うれしいです。

はじめに

この記事では、Poisson方程式の概要→差分方程式→アルゴリズム→Haskellで書いたコードという順で説明していきます。

Poisson方程式とは

Poisson方程式は二階の偏微分方程式で、次の様に表されるもののことを言います。

Δ ϕ = f

ここで、 $Δ$ は微分演算子で

Δ = \nabla \cdot \nabla \nabla = (\frac{\partial}{\partial x}, \frac{\partial}{\partial y}, \frac{\partial}{\partial z})

となります。

この記事では簡単のため二次元の系を扱うことにして、Poisson方程式として次の電位と電荷密度に関する方程式を解いてみます。3次元への拡張も簡単にできるので是非やってみて下さい。

Δ ϕ = - \frac{ρ}{ϵ_{0}}

ただし、 $ϕ (x, y)$ は座標 $(x, y)$ における電位、 $ρ (x, y)$ は電荷密度、 $ϵ_{0}$ は真空中の誘電率を表します。

差分方程式を導出する

解きたい方程式

Δ ϕ = - \frac{ρ}{ϵ_{0}}

は次のようにも表せます。

\frac{\partial^{2} ϕ}{\partial x^{2}} + \frac{\partial^{2} ϕ}{\partial y^{2}} = - \frac{ρ}{ϵ_{0}}

ここで、二階の偏導関数は格子幅 $Δ x$ を用いて、

\frac{\partial^{2} ϕ}{\partial x^{2}} ≃ \frac{ϕ (x + Δ x, y) - 2 ϕ (x, y) + ϕ (x - Δ x, y)}{Δ x^{2}}

と近似できることが知られています。このような差分の取り方を中心差分と言います。
これを用いて偏導関数を置き換えると、次を得ます。

\frac{ϕ (x + Δ x, y) - 2 ϕ (x, y) + ϕ (x - Δ x, y)}{Δ x^{2}} + \frac{ϕ (x, y + Δ y) - 2 ϕ (x, y) + ϕ (x, y - Δ y)}{Δ y^{2}} = - \frac{ρ (x, y)}{ϵ_{0}}

問題を簡単にするために、

Δ x = Δ y = δ

として、

i, j \in Z, ϕ (x + i δ, y + j δ)

を単に

ϕ_{i, j}

と表記することにします。そうすると、次の差分方程式を得ます!

ϕ_{i, j} = \frac{1}{4} (ϕ_{i + 1, j} + ϕ_{i - 1, j} + ϕ_{i, j + 1} + ϕ_{i, j - 1} + δ^{2} \frac{ρ_{i, j}}{ϵ_{0}})

つまり、ある一点 $(i, j)$ における電位 $ϕ_{i, j}$ を求めるには周囲の4点での電位を平均した値に $δ^{2} \frac{ρ_{i, j}}{4 ϵ_{0}}$ を足せばよいと、この方程式は言っています。

アルゴリズム

得られた差分方程式を用いて具体的に解く手法を考えます。

まず、対象とする $x, y$ 方向の区間を $n$ 分割し、格子幅を $δ$ とします。すると $x y$ 平面は次のように分割されます。

この場合、対象とする区間は $\forall x \in [0, 1], \forall y \in [0, 1]$ です。
それぞれの点には物理量 $ϕ, ρ$ がありこれらの値を差分方程式から求めれば良いのですが、 $i = 0, n$ や $j = 0, n$ の時は周囲の値を参照することができないので、境界条件として

\forall i \forall j, ϕ_{0, j} = ϕ_{n, j} = ϕ_{i, 0} = ϕ_{i, n} = 0

を設けてやります。

そうすると、具体的には次のような連立方程式を解けば良いことになります。

ϕ_{1, 1} = \frac{1}{4} (ϕ_{2, 1} + ϕ_{0, 1} + ϕ_{1, 2} + ϕ_{1, 0} + δ^{2} \frac{ρ_{1, 1}}{ϵ_{0}}) ϕ_{1, 2} = \frac{1}{4} (ϕ_{2, 2} + ϕ_{0, 2} + ϕ_{1, 3} + ϕ_{1, 1} + δ^{2} \frac{ρ_{1, 2}}{ϵ_{0}}) ⋮ ϕ_{n - 1, n - 1} = \frac{1}{4} (ϕ_{n, n - 1} + ϕ_{n - 2, n - 1} + ϕ_{n - 1, n} + ϕ_{n - 1, n - 2} + δ^{2} \frac{ρ_{n - 1, n - 1}}{ϵ_{0}})

しかし、実は困ったことに $ϕ_{i, j} (1 \leq i \leq n - 1, 1 \leq j \leq n - 1)$ の値も分からないのですが、上記の連立方程式はヤコビ法やガウス-ザイデル法と呼ばれる連立方程式の反復解法を用いることができる形になっています。(詳しくはヤコビ法を参照してください。)
今回はヤコビ法を用いることにして、適当に $ϕ_{i, j}^{(0)}$ の値を設定し、 ${\vec{x}}^{(k + 1)} = D^{- 1} {\vec{b} - (L + U) {\vec{x}}^{(k)}}$ という形の漸化式を上記の方程式に対して繰り返し適用し、

m a x | ϕ_{i, j}^{(k + 1)} - ϕ_{i, j}^{(k)} | < ϵ

という条件を満たした時、

ϕ_{i, j}^{(k + 1)}

を解として出力します。ただし、関数

m a x

は

i, j

の組み合わせを全て走査してその中の最大値を返す関数で、

ϵ

は小さな数でプログラムの停止基準になります。

問題設定

今回実際に数値計算してみる系として次のようなものを考えます。

平面 $1 [m^{2}]$ を対象として境界を含んで外側は接地されていて $0 [V]$ で、中心に半径 $10 [c m]$ で電荷密度 $1.0 \times 10^{- 8}$ の電荷を設置した状況で、各点の電位を求めます。

Haskellプログラムの説明

それでは、Haskellでゴリゴリ書いていきましょう!
最初はもちろんライブラリのインポートです。

Haskell

module PoissonEqSolver where
import Data.Array
import Text.Printf

今回は主なデータ構造として配列を用いるのでData.Arrayを、出力する時に簡単に整形できるのでText.Printfをインポート
しています。(Arrayはboxedでimutableな配列です。)

続いて、定数たちを宣言します。

Haskell

ε0 = 8.85E-12 --真空中の誘電率
n = 100 --区間はn分割される
δ = 1 / fromIntegral n --格子幅

上から、真空中の誘電率、分割数、格子幅です。

ところで、Haskellの配列はarray関数を用いて次の形で宣言します。

Haskell

arr = array (インデックスの最小値,インデックスの最大値) [(インデックス,要素) | インデックスの生成]

arrの型はArray i eでiはインデックスの型、eは要素の型となります。
ちなみに、インデックスへのアクセスは!関数でやります。
これを使って仮の電位分布と電荷分布を二次元配列で宣言します。

Haskell

φ0 :: Array (Int, Int) Double
φ0 = array ((0,0),(n,n)) [((x,y), 0) | x <- [0..n], y <- [0..n]] --仮の電位分布

ρ0 :: Array (Int, Int) Double
ρ0 = array ((0,0),(n,n)) [((x,y), f x y) | x <- [0..n], y <- [0..n]] --電荷密度の分布
    where
        f x y | (δ*fromIntegral (x - div n 2))^2 + (δ*fromIntegral (y - div n 2))^2 <= 0.1^2 = 1.0E-08 --円状に電荷密度を分布させる
              | otherwise = 0

仮の電位分布φ0は全ての要素を0にセットしておいて、電荷分布ρ0には中心に円状に電荷を分布をさせています。(fromIntegral関数を多用するとコードが汚くなっちゃうのはしょうがないのでしょうか...?)

それでは、漸化式を記述する関数nextを実装します。

Haskell

next :: Array (Int, Int) Double -> Array (Int, Int) Double -> Array (Int, Int) Double
next ρ φ = φ // [((x,y),f x y) | x <- [1..n-1], y <- [1..n-1]]
    where
        f x y  = (/4) $ φ ! (x+1,y) + φ ! (x-1,y) + φ ! (x,y+1) + φ ! (x,y-1) + δ^2 * ρ ! (x,y) / ε0

where句で宣言されている関数fはインデックスx,yから周囲の物理量にアクセスして平均した値を返します。fをインデックス全体に渡ってmapしてあげることで次のステップの状態に移ります。

得られた電位をgnuplotで表示できるように、雑に外部出力関数を作ります。

haskell

output :: Array (Int,Int) Double -> IO ()
output φ = do
    let filePath = "./result.dat"
    writeFile filePath ""
    mapM_ (appendFile filePath) $ do
        x <- [0..n]
        y <- [0..n]
        return $ printf "%d %d %.15f\n" x y (φ ! (x,y))

filePathに出力先のパスを宣言、writeFile関数でとりあえずファイルを開きます。
その後、mapM_でリスト全体にappend関数を適用することで、filePathにx y φ(x,y)の順で逐次書き込みます。(初めてリストモナドを使ってみました、かっこいいですね。)

最後に、実際に系を解く関数を用意しておしまいです。

Haskell

solve :: Double -> Array (Int,Int) Double -> Array (Int,Int) Double -> IO ()
solve ε ρ φ | error < ε = do
                putStrLn "Write result to ./result.dat \nWait..."
                output φ'
                printf "Finished.\n"
            | otherwise = solve ε ρ φ'
    where
        φ' = next ρ φ
        error = maximum [abs ( φ ! (x,y) - φ' ! (x,y) ) | x <- [0..n], y <- [0..n]]

この関数を端的に説明すると、現時点での解と後の解との誤差をerrorで評価してε未満ならば、output関数に電位を渡す、そうでなければ、次のステップの電位を自身に引数として渡す、ということをします。where句では、次のステップの電位であるφ'と誤差errorが定義されています。

40行でPoisson方程式を解く

まとめとして、ソースコード全体を載せておきます。ぴったり40行だよ、やったね!

Haskell

module PoissonEqSolver where
import Data.Array
import Text.Printf

ε0 = 8.85E-12 --真空中の誘電率
n = 100 --区間はn分割される
δ = 1 / fromIntegral n --格子幅

φ0 :: Array (Int, Int) Double
φ0 = array ((0,0),(n,n)) [((x,y), 0) | x <- [0..n], y <- [0..n]] --仮の電位分布

ρ0 :: Array (Int, Int) Double
ρ0 = array ((0,0),(n,n)) [((x,y), f x y) | x <- [0..n], y <- [0..n]] --電荷密度の分布
    where
        f x y | (δ*fromIntegral (x - div n 2))^2 + (δ*fromIntegral (y - div n 2))^2 <= 0.1^2 = 1.0E-08 --円状に電荷密度を分布させる
              | otherwise = 0

next :: Array (Int, Int) Double -> Array (Int, Int) Double -> Array (Int, Int) Double
next ρ φ = φ // [((x,y),f x y) | x <- [1..n-1], y <- [1..n-1]]
    where
        f x y  = (/4) $ φ ! (x+1,y) + φ ! (x-1,y) + φ ! (x,y+1) + φ ! (x,y-1) + δ^2 * ρ ! (x,y) / ε0

output :: Array (Int,Int) Double -> IO ()
output φ = do
    let filePath = "./result.dat"
    writeFile filePath ""
    mapM_ (appendFile filePath) $ do
        x <- [0..n]
        y <- [0..n]
        return $ printf "%d %d %.15f\n" x y (φ ! (x,y))

solve :: Double -> Array (Int,Int) Double -> Array (Int,Int) Double -> IO ()
solve ε ρ φ | error < ε = do
                putStrLn "Write result to ./result.dat \nWait..."
                output φ'
                printf "Finished.\n"
            | otherwise = solve ε ρ φ'
    where
        φ' = next ρ φ
        error = maximum [abs ( φ ! (x,y) - φ' ! (x,y) ) | x <- [0..n], y <- [0..n]]

Haskellは楽しい!

gnuplotで表示する

ghciでsolve 1e-05 ρ0 φ0を入力しEnterキーを押して待ちます。
result.datが吐き出されます。

出力されたresult.datをgnuplotで可視化してみました。z軸が電位[V]の大きさを表しています。

いい感じですね。

感想

今回は配列を用いてPoisson方程式を解いてみました、楽しかったです。
ただ、想像以上に処理に時間がかかり、如何にして速度を出すかが課題だと思いました。(IOUArrayでSOR法で解いてみたい、Vectorが早いと風のうわさで聞いたので使ってみたい。)
本当は解析解との比較などもやりたかったのですが、それは他の強い文献にまかせて自粛させていただきます。

ここまで見てくれた人、ありがとうございます!

最後に

PoissonがPoisonになってないかめっちゃ確認しました。

[Haskell] 40行でPoisson方程式を解く

注意

はじめに

Poisson方程式とは

差分方程式を導出する

アルゴリズム

問題設定

Haskellプログラムの説明

40行でPoisson方程式を解く

gnuplotで表示する

感想

最後に