今日も株システムトレード情報局面白かったですね〜笑

特に逆指値と成行のバランスや、仕掛け位置によって順張りか逆張りかが変わるという点が非常に参考になりましたね。

実際個人的にも

（1）ポートフォリオ内の逆指値戦略と成行戦略のバランス
（2）バランスがいい1銘柄投入額はどれぐらいか？

という点を研究しておりまして、

まず（1）からですと、実際ポートフォリオ内が全て逆指値でもいいのですが、

逆指値戦略は約定率が低い特性があるため、ブレイク狙いには最適ですが押し目がとりづらい印象があります苦笑

そのためですが、押し目狙いはもっと約定率が高い成行・指値・寄指などでもいいのかもしれないですね〜。

（2）の1銘柄投入額は資金量によっても変わってくるためなかなか難しいところですが、

個人的にバランスがいい1銘柄投入額はおおむね30〜50万のあたりのような気がしています。

これは最近で一番分かりやすいところですと、ガンホーやナノキャリア、ジャパンティッシュなどは最低30万以上でないと仕掛けられないためですね苦笑

…ガンホーはすでにこの投入額でもオーバーしていますが汗

株では最低単元の影響によりやはりある程度は投入額が必要だとは思っておりまして、

もちろんトレード日記側のように1銘柄投入額を下げることも可能ではありますが、

ナノキャリアやジャパンティッシュへのシグナルが出なくなったり、要するに投資機会といいますか投資対象銘柄数が減るわけですね。

各戦略でも1銘柄投入額が40万近辺の資金500万ファイルの成績がいいことを考えますと、

やはりこの40万円近辺という投入額にバランスの良さを感じていたりはします。

そういえば、発注ツールの方のソースを変更しましたので以下に掲載させていただきます。

今回はUWSCファイルをEXE化し、さらに外部に設定ファイルを持たせるような形にしていますが、

未知のエラーはまだありそうな気もしますが、ひとまずは動く感じではあります笑

■UWSC側（Dドライブ直下に「UWSC」フォルダを作り、その中にEXE化したorder.exeを保存）
----------------------------------------------------
Public LOGINURL = "https://lv01.live-sec.co.jp/webbroker3/44/i/WEB3Index.jsp?aa_odrdv=2" // ライブスターログインURL
Public LOGFILE = "./log.txt" // ログファイルへのパス
Public CONFIGFILE = "./config.txt" // 設定ファイルへのパス
Public IE = 0 // IEオブジェクト用
Public SLEEPTIME // 画面遷移時の休止時間
Public CHANGESG // 信用建禁止銘柄の場合現物で発注する場合：1 しない場合
Public TEST // テストの場合1 実際に発注する場合0

// 設定ファイル読み込み
fid = FOPEN(CONFIGFILE,F_READ)
SLEEPTIME = getNumber(FGET(fid, 1))*0.1
CHANGESG = getNumber(FGET(fid, 2))
TEST = getNumber(FGET(fid, 3))
FCLOSE(fid)

//PARAM_STR[0]: 証券会社 ライブスターLS
//PARAM_STR[1]: ログインID
//PARAM_STR[2]: ログインパスワード
//PARAM_STR[3]: 取引パスワード
//PARAM_STR[4]: 制度信用S 現物G
//PARAM_STR[5]: 買いL 売りS
//PARAM_STR[6]: 銘柄コード
//PARAM_STR[7]: 銘柄名
//PARAM_STR[8]: 成行N 引成H 指値S 寄指Y 引指I 不成F 逆指値G 逆指値（指値指定）J
//PARAM_STR[9]: 株数
//PARAM_STR[10]: 指値
//PARAM_STR[11]: 逆指値

login(PARAM_STR[1], PARAM_STR[2], PARAM_STR[3], PARAM_STR[4], PARAM_STR[5], PARAM_STR[6], PARAM_STR[7], PARAM_STR[8], PARAM_STR[9], PARAM_STR[10], PARAM_STR[11])

order(PARAM_STR[3], PARAM_STR[4], PARAM_STR[5], PARAM_STR[6], PARAM_STR[7], PARAM_STR[8], PARAM_STR[9], PARAM_STR[10], PARAM_STR[11])

//■数字を取得
Function getNumber(str)
Dim regex = CREATEOLEOBJ("VBScript.RegExp")
WITH regex
.Pattern = "\D" // 数字以外の文字に一致
.Global = TRUE // 全部が対象
str2 = .Replace(str, "") // 一致した文字を""に置き換える
ENDWITH
Result = str2
Fend

//■日付取得
Function getDateStr()
GETTIME()
Result = G_TIME_YY4 + "/" + G_TIME_MM2 + "/" + G_TIME_DD2 + " " + G_TIME_HH2 + ":" + G_TIME_NN2 + ":" + G_TIME_SS2
Fend

//■指値文字列取得
Function getSashineStr(ls, how, sashine)
Dim sashineStr = ""
ifB how = "N" OR how = "H" OR how = "G"
sashineStr = ""
else
sashineStr = sashine + "円"
Endif
Result = sashineStr
Fend

//■逆指値文字列取得
Function getSashineGStr(ls, how, sashineG)
Dim sashineGStr = ""
ifB how = "G" OR how = "J"
ifB ls = "S" // 信用売り（逆指値）
sashineGStr = sashineG + "円以下"
else // 買い（逆指値）
sashineGStr = sashineG + "円以上"
Endif
else
sashineGStr = ""
Endif
Result = sashineGStr
Fend

//■スリープ
Procedure ieSleep(IE)
REPEAT
SLEEP(SLEEPTIME)
UNTIL !IE.busy AND IE.readystate=4
Fend

//■エラー時の処理
Procedure error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, ok, msg)

Dim fid = FOPEN(LOGFILE, F_READ or F_WRITE)
FPUT(fid, getDateStr() + "," + sgStr + "," + lgStr + "," + mCode + "," + mName + "," + howStr + "," + kabusu + "株" + "," + getSashineStr(ls, how, sashine) + "," + getSashineGStr(ls, how, sashineG) + "," + ok + "," + msg)
FCLOSE(fid)

IE.quit
EXITEXIT
Fend

//■信用→現物変更時の処理
Procedure orderChange(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, ok, msg)

Dim fid = FOPEN(LOGFILE, F_READ or F_WRITE)
FPUT(fid, getDateStr() + "," + sgStr + "," + lgStr + "," + mCode + "," + mName + "," + howStr + "," + kabusu + "株" + "," + getSashineStr(ls, how, sashine) + "," + getSashineGStr(ls, how, sashineG) + "," + ok + "," + msg)
FCLOSE(fid)

IESETDATA(IE,True,"","7.戻る")
ieSleep(IE)

IELINK(IE,"ﾒｲﾝﾒﾆｭｰへ")
ieSleep(IE)

order(orderPw, "G", ls, mCode, mName, how, kabusu, sashine, sashineG)
Fend

//■発注時の処理
Procedure complete(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, ok, msg)

Dim fid = FOPEN(LOGFILE, F_READ or F_WRITE)
FPUT(fid, getDateStr() + "," + sgStr + "," + lgStr + "," + mCode + "," + mName + "," + howStr + "," + kabusu + "株" + "," + getSashineStr(ls, how, sashine) + "," + getSashineGStr(ls, how, sashineG) + "," + ok + "," + msg)
FCLOSE(fid)

IE.quit
EXITEXIT
Fend

//■ログイン
Procedure login(loginId, loginPw, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG)

sgStr = "現物" // 現物or信用
lgStr = "買い" // 買いor売り
howStr = "成行" // 仕掛け方法

ifB sg = "S"
sgStr = "信用" // 信用
ifB ls = "S" // 信用売り
lgStr = "売り" // 売り
Endif
Endif

IE = CREATEOLEOBJ("InternetExplorer.Application")
IE.visible = True
IE.navigate(LOGINURL)
ieSleep(IE)

IESETDATA(IE,loginId,"aa_accd")
IESETDATA(IE,loginPw,"lg_pw")
IESETDATA(IE,True,"","1.実行")
ieSleep(IE)

// 該当銘柄が存在しない場合
ifB pos("正しくありません",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "ログインID/パスワードエラー")
Endif

IELINK(IE,"ﾒｲﾝﾒﾆｭｰへ")
ieSleep(IE)
Fend

//■発注
Procedure order(orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG)

sgStr = "現物" // 現物or信用
lgStr = "買い" // 買いor売り
howStr = "成行" // 仕掛け方法
pdcd = "eq_pdcd" // 銘柄検索
ttp_x = "eq_ttp_x" // 特定口座
odqt = "eq_odqt" // 株数
ectpodpdiv_x = "eq_ectpodpdiv_x" // 注文方法
lpr = "eq_lpr" // 指値
sodcpr = "eq_sodcpr" // 逆指値
ectpodpdiv_x = "eq_ectpodpdiv_x" // 逆指値の執行条件
edttp_x = "eq_edttp_x" // 当日限り

ifB sg = "S"

sgStr = "信用" // 信用
pdcd = "mr_pdcd" // 銘柄検索（信用）
ttp_x = "mr_ttp_x" // 特定口座（信用）
odqt = "mr_odqt" // 株数（信用）
ectpodpdiv_x = "mr_ectpodpdiv_x" // 注文方法（信用）
lpr = "mr_lpr" // 指値（信用）
sodcpr = "mr_sodcpr" // 逆指値（信用）
ectpodpdiv_x = "mr_ectpodpdiv_x" // 逆指値の執行条件（信用）
edttp_x = "mr_edttp_x" // 当日限り（信用）

ifB ls = "S" // 信用売り

lgStr = "売り" // 売り

// 信用取引をクリック
IELINK(IE,"信用取引")
ieSleep(IE)

// 新規売をクリック
IELINK(IE,"新規売")
ieSleep(IE)

else // 信用買い

// 信用取引をクリック
IELINK(IE,"信用取引")
ieSleep(IE)

// 新規買をクリック
IELINK(IE,"新規買")
ieSleep(IE)
Endif

else // 現物買い

// 株式現物をクリック
IELINK(IE,"株式現物")
ieSleep(IE)

// 買付をクリック
IELINK(IE,"買付")
ieSleep(IE)
Endif

// 銘柄検索
IESETDATA(IE,mCode,pdcd)
IESETDATA(IE,True,"","1.実行")
ieSleep(IE)

// 該当銘柄が存在しない場合
ifB pos("優先市場が設定されていません",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "該当銘柄なし")
Endif

ifB how = "G" OR how = "J" // 逆指値
howStr = "逆指値"
IESETDATA(IE,"逆指値S","jsp_cond_chg")
IESETDATA(IE,True,"","4.画面切替")
ieSleep(IE)
IESETDATA(IE,sashineG,sodcpr)
Endif

// 特定口座
IESETDATA(IE,1,ttp_x,"1")

// 株数
IESETDATA(IE,kabusu,odqt)

ifB how = "H" // 引成
howStr = "引成"
IESETDATA(IE,"引成",ectpodpdiv_x)
elseif how = "S" // 指値
howStr = "指値"
IESETDATA(IE,"指値",ectpodpdiv_x)
IESETDATA(IE,sashine,lpr)
elseif how = "Y" // 寄指
howStr = "寄指"
IESETDATA(IE,"寄指",ectpodpdiv_x)
IESETDATA(IE,sashine,lpr)
elseif how = "I" // 引指
howStr = "引指"
IESETDATA(IE,"引指",ectpodpdiv_x)
IESETDATA(IE,sashine,lpr)
elseif how = "F" // 不成
howStr = "不成"
IESETDATA(IE,"不成",ectpodpdiv_x)
IESETDATA(IE,sashine,lpr)
elseif how = "J" // 逆指値（指値指定）
howStr = "逆指値（指値指定）"
IESETDATA(IE,sashine,lpr)
IESETDATA(IE,"指値",ectpodpdiv_x)
Endif

// 当日限り
IESETDATA(IE,1,edttp_x,"1")

// 発注確認
IESETDATA(IE,True,"","1.実行")
ieSleep(IE)

// エラーチェック
ifB pos("バッチ処理中",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "注文時間外")
elseif pos("売買単位が正しくありません",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "売買単位エラー")
elseif pos("不足しています",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "余力不足")
elseif pos("超えています",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "値幅制限エラー")
elseif pos("抵触",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "アップティックルール規制")
elseif pos("制限されています",IE.document.body.innerText)
ifB sg = "S" AND ls = "L" AND CHANGESG = 1 // 現物で発注
orderChange(sgStr, lgStr, howStr, orderPw, "G", ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "信用規制銘柄")
else
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "信用規制銘柄")
Endif
elseif pos("できません",IE.document.body.innerText)
ifB sg = "S" AND ls = "L" AND CHANGESG = 1 // 現物で発注
orderChange(sgStr, lgStr, howStr, orderPw, "G", ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "信用不可")
else
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "信用不可")
Endif
Endif

// 発注
IESETDATA(IE,orderPw,"aa_pw")

ifB TEST = 0 // 実際に発注する場合
IESETDATA(IE,True,"","1.実行")
ieSleep(IE)

ifB pos("正しくありません",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "取引パスワードエラー")
Endif

complete(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "○", "発注完了")
else // テストの場合
complete(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "○", "発注完了（テスト）")
Endif

Fend
----------------------------------------------------

■設定ファイル（Dドライブ直下に「UWSC」フォルダを作り、その中にconfig.txtという名前で保存）
----------------------------------------------------
SLEEPTIME = 1 // 画面遷移時の休止時間
CHANGESG = 1 // 信用建禁止銘柄を現物で発注する場合１ しない場合０（半角）
TEST = 1 // テストの場合１ 実際に発注する場合０（半角）
----------------------------------------------------

■コマンドプロンプト側
----------------------------------------------------
"D:\UWSC\order.exe" "LS" "証券会社ログインID" "証券会社ログインパスワード" "証券会社取引パスワード" "G" "L" "4755" "楽天" "G" "100" "1101" "1102"
----------------------------------------------------