EXCEL VBA フォームの動的に作成した各コントロールのイベントについて

A1からA3までデータがある場合のコードです。

ユーザーフォームのコード
Option Explicit

Private btncls() As Class1

Private Sub UserForm_Initialize()
Dim btn As MSForms.CommandButton
Dim Top As Integer
Dim N As Integer
Dim i As Integer

N = Cells(1, 1).End(xlDown).Row 'データ数
ReDim btncls(N)

Do While i < N
i = i + 1
Top = (i * 40) - 20
Set btn = Me.Controls.Add("forms.commandbutton.1", "cells(i,1).value")
With btn
.Caption = Cells(i, 1).Value
.Top = Top
.Left = 20
Set btncls(i) = New Class1
btncls(i).SetBtn = btn
btncls(i).SetMacro = "test" & i
End With
Loop
With Me
.Width = 120
.Height = Top + 60
End With
End Sub

Public Sub test1()
MsgBox "test1"
End Sub

Public Sub test2()
MsgBox "test2"
End Sub

Public Sub test3()
MsgBox "test3"
End Sub

クラスモジュールを挿入して以下のコードを貼り付けてください。
Option Explicit

Private WithEvents btn As MSForms.CommandButton
Private macro As String

Private Sub btn_Click()
CallByName UserForm1, macro, VbMethod
End Sub

Public Property Let SetBtn(ByVal vNewValue As Variant)
Set btn = vNewValue
End Property

Public Property Let SetMacro(ByVal vNewValue As Variant)
macro = vNewValue
End Property

基本は
http://oshiete.goo.ne.jp/qa/504573.html
こんな感じなのでしょうけど、
複数に対してどうするのかは・・・？
⇒各ボタンのイベントがどうなっているのかわからないし、
何よりクラスモジュールは難しい・・・・・

http://qanda.rakuten.ne.jp/qa4033874.html
こちらも参考になりそうな気もするのですが
私の頭では難解で。。。