何かオペレーションが行われたかを監視して、５分ごとにそれをチェックし、オペレーションがされなかったらブックを閉じるというマクロを組んでみました。（最後のオペレーションから５分間監視、ではなく、ブックを開いてから５分間隔でチェックするので、多少のタイムラグがあります）

しかし、「何もしなかったら」というのを検知する方法がわからなかったため、ちょっと強引ですが ThisWorkbook のイベントほとんど全てをを定義して、「何かした」というフラグを立てるという方法になっています。
そのため、ThisWorkbook のイベントで拾えない操作をしたときにも強制終了する可能性があります。

まず、標準モジュールに以下のマクロを貼り付けてください。
"00:05:00"という箇所が「５分」を定義しているところなので、時間間隔を調整したいときはそこをいじってください。



Public Operated As Boolean

Sub SetTimer()
　Application.OnTime Now + TimeValue("00:05:00"), "CloseMe"
End Sub

Sub CloseMe()
　If Operated Then
　　Operated = False
　　SetTimer
　　Exit Sub
　End If
　
　'ブックの上書き保存
　ActiveWorkbook.Save
　' 保存確認を避けるため、保存済みにする
　ThisWorkbook.Saved = True

　' 他にブックが開いていなければ、Excelを終了する
　If Workbooks.Count <= 1 Then Application.Quit

　' 本ブックをClose
　ThisWorkbook.Close False
End Sub



そして、ThisWorkbook に以下のマクロを貼り付けてください。



Private Sub Workbook_Open()
　Operated = False
　SetTimer
End Sub

Private Sub Workbook_BeforePrint(Cancel As Boolean)
　Operated = True
End Sub

Private Sub Workbook_Deactivate()
　Operated = True
End Sub

Private Sub Workbook_Activate()
　Operated = True
End Sub

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
　Operated = True
End Sub

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
　Operated = True
End Sub

Private Sub Workbook_SheetBeforeRightClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
　Operated = True
End Sub

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
　Operated = True
End Sub

Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
　Operated = True
End Sub

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
　Operated = True
End Sub

Private Sub Workbook_WindowActivate(ByVal Wn As Window)
　Operated = True
End Sub

Private Sub Workbook_WindowDeactivate(ByVal Wn As Window)
　Operated = True
End Sub

Private Sub Workbook_WindowResize(ByVal Wn As Window)
　Operated = True
End Sub



ご覧の通り、Workbook_Open()だけは初期設定をしていますが、その他は「何かイベントが発生したらフラグをTrueにする」の羅列です。

単にExcelのファイルを開いて、マウスのホイールでスクロールしながらあちこちシートを眺めているだけの場合など、セル操作や印刷などの操作がない場合にも強制終了されてしまうので、そこはご承知ください。