ヨーロッパや米国の気象機関では、プログラムのソースコードを理解しやすく 管理しやすいものにし、またソースコードの交換を容易にするため、プログラミ ングルールが作成されている。日本でもこれらを参考にして、気象庁数値予報課 と気象研究所気候研究部・予報研究部が中心となって日本版標準コーディングル ールを作成している。その目的は、プログラミング・スタイルを統一することに より、可読性と移植性を高め、維持管理を容易にすることである。この目的に賛 同する開発担当者は、このルールに従いプログラムを作成し、同時にこのルール を改善するよう努力してほしい。

　このプログラミングルールではFortran90 の使用を前提としている。Fortran 90 は、 FORTRAN77 と互換性を保ちながら様々な機能を付加したもので、従来と比 較して多くの点で改良されている。最新の JIS 規格は Fortran 95 であるが、 Fortran 90 しか使えない環境が依然多い状況であると思われるので、Fortran 95 の新機能は当面使わないことを推奨する。

　対象とするプログラムとして、気象予報モデルとデータ同化モデルを想定して はいるが、高速で実行する必要がある大規模プログラムを多人数で共同開発する 場合には、異分野でも役に立つと考えている。

　一部のルールについては断定的に記述していない部分がある。今後 Fortran 90 についてより多くの経験をつむことにより、今後の改訂版では追加・削除・変更 されることを了解していただきたい。

• フリーフォーマット（自由形式）

  7-72桁に文を書かなければならない等の制約がなくなり、それ以外の桁位置 に書いた文字が無視されるなどの誤りを防ぐことができる。

• １ファイルには同名のプログラム単位１つを格納

  プログラム単位とは、主プログラム、外部関数、外部サブルーチン、モジュ ール、BLOCKDATA のいずれかである。たとえば、外部サブルーチン SUB は sub.f90 に保存されるべきである。
  こうしておけばプログラムを読むときにファイルを探しやすい。また、サブ ルーチンを書き換えた場合に他のプログラム単位をコンパイルしなおすこと がなくなるので、コンパイル時間が短くなる。

• 名前

  いつも主プログラムは program 文ではじめること。また end 文としては "end program name" や "end subroutine name" 等の形を使 用すること。

• 継続記号

  継続行を追加する場合の継続記号（&:アンド記号）は、行末（開始行の 終わりの文字として）だけではなく行頭（継続行の最初の文字として）にも つけること。継続行であるということがはっきりと区別できるようになる。

• 字下げ（インデンテーション）

  読みやすさのため、2桁づつの幅で字下げすること。字下げとはプログラム の構造上ひとまとまりとなる文をそのほかの文に比べて2字右側の桁位置か ら書き始めることである。
  字下げを行う「まとまり」とはプログラム単位（subroutine）、引用使用宣 言（interface）、実行部ブロック（do, if など）である。これらの終わり の文はすべて「end」で始まる文なので、「end まで字下げ」と覚えれば簡 単である。
  字下げされた範囲の中の注釈行も字下げすること。これによって、行頭の空 白でない最初の桁位置を追うだけでプログラムのアルゴリズム構造が見出せ るようになる。
  継続行は開始行に対して2字字下げすること。

• 空白

  読みやすさのため、名前と演算子など、字句の間に適切な空白を入れ、同じ スタイルを一貫して用いること。英文タイプの句読法に従うのが望ましい。

  • 演算子の前後に空白を入れる。(例: 1 + 2)
  • コンマ、コロン、セミコロンの後に空白を入れる。(例: a, b, c)
  • 括弧類の内側に入れない。(例: array(index))

  またブロックではない一群の文は前後の文との間に空行を入れて区別すること。
  空白は原則として1個とするが、似たような構成の代入文が連続するときに 余分な空白をいれて等号の桁位置をそろえ、類似性を見比べやすくするなど してもよい。

• implicit none

  すべてのプログラム単位の冒頭（use 文があるときはその直後) に implicit none 文を書くこと。そしてすべての変数・定数は明示的に宣言すること。 これによって、宣言されていない名前を用いるとコンパイルエラーを起こす ので、名前のつづり間違えによるバグを防ぐことができる。

• １行に複数の文を書かない

  プログラムがわかりにくくなる。

• 意味がわかる名称をつける

  変数名やサブルーチン名は、その役割に基づいた名前をつけておくとプログ ラムを読む際にその意味や構造を把握しやすい。

• 変数の宣言方法

  FORTRAN 77 では型宣言文と属性を与えるための文 (SAVE, DATA, DIMENSION, PARAMETER, など) が別であったため、同じ名前の列を何度も書く必要が あった。Fortran 90 では型宣言文で属性をすべて設定できるようになった ため、すべての属性を型宣言文で指定すること。たとえば以下の3つのコー ドはまったく等価である。

  昔ながらの書き方	INTEGER N DIMENSION N(2) SAVE N DATA N / 400, 224
  ◎推奨する書き方	integer, save:: n(2) = (/400, 224/)
  ×推奨しない書き方	integer, save, dimension(2):: n = (/400, 224/)

  上記例3行目のような、型宣言文の dimension 属性は使わないこと。 代わりに2行目のような書き方を用いること。

• 引数の入出力特性

  識別を容易にするためintent(in), intent(out), intent(inout) をつける。 例えば intent(in) がつけられた変数の値を変更する文が存在すると、コン パイル時にエラーが発生し、デバッグを助ける。
  なお、手続のモジュール化または interface ブロックによって引用仕様を 明示することにより、さらにその恩恵を受けることが可能である。

• 入出力のフォーマット情報

  文番号を伴ったformat 文は禁止する。代わりに入出力文の fmt 指定子に記 述すること。

• 配列表記

  プログラムの行数が少なくなるので、可能であれば使用すること。配列か変 数かの区別をつけて読みやすくするため、カッコ内に配列の形状を示すこと。

  昔ながらの書き方	DIMENSION(N) X, Y DO 300 I = 1, N   X(I) = Y(I) 300 CONTINUE
  ◎推奨する書き方	real:: x(n), y(n) x(1:n) = y(1:n)
  ×推奨しない書き方	x(:) = y(:) または x = y

  並列最適化コンパイラの動作を助け、バグを少なくするため、配列代入文の 上下限指定は省略しないほうがよい。

• 論理比較

  従来の .GT., .GE., .EQ., .LT., .LE., .NE. の代わりにそれぞれ >, >=, ==, <, <=, /= を使用する。数学表記に近いこの新しい構文 の方が意味がわかりやすい。

• goto 文

  goto 文を使うとプログラムがわかりにくくなることが多い。Fortran に限 らず、ほとんどのプログラムはループと条件分岐だけで書くことができ、そ うすることが望ましいと考えられている（構造化プログラミング）。
  FORTRAN 77 では固定長のループしか表現できないため GOTO 文を用いる必 要があったが、do のあとの繰り返し指定を省略すると無限ループを表し、 ループの途中からの脱出は exit 文で行えるようになったので、構造化プロ グラミング理論で用いられるすべてのループが GOTO 文なしで書ける。

３．１　モジュールの使い方

３．１．１　モジュールの３つの使用方法

　モジュールは Fortran90 の新しい機能のうち、最も重要な機能の１つである。 しかし、これを乱用すると分かりにくいプログラムになってしまう。（例えば、 モジュールの共有変数の値は、そのモジュール外のいろいろなサブルーチンから 自由に変更可能であるが、その自由を認めると、その共有変数がどこでどういう タイミングで変更されるのか理解が難しいプログラムになってしまう。）
　そこで、プログラムを分かりやすいものにするため、モジュールの使用方法を 以下の３つの類型に限定する。

• 定数参照型モジュール

  定数を参照するためのモジュール。

• 変数参照型モジュール

  変数を参照するためのモジュール。common文をこれに置き換える。

• パッケージ型モジュール

  パッケージを扱うためのモジュールである。（パッケージとは、ある機能を 持つサブルーチン群のこと。例えば高速フーリエ変換や、気象モデルにおけ る大気放射など。）共有変数・初期化サブルーチン・実行サブルーチン・局 所サブルーチンからなる。

３．１．２　定数参照型モジュール

　いろいろなサブルーチンで使用する定数を、定数参照型モジュールにまとめ る。include と異なり、use prm, only : imax　などと使用したいパラメータ だけ use できる。また、この場合、prm に imax の宣言がなければコンパイ ル時にエラーが発生してくれて、親切である。

• 定数参照型モジュールの例１　（prm_resol.F90）

  module prm_resol
  !
  ! 配列の大きさ(解像度)等を表す変数を設定
  !
    implicit none
    integer,parameter :: imax = 128
    integer,parameter :: jmax = 64
     ( 中略 )
  end module prm_resol

• 定数参照型モジュールの例２　（prm_phconst.F90）

  module prm_phconst
  !
  ! 物理定数を表す変数を設定する
  !
    implicit none
    real(8),parameter :: cp   = 1004.6D0   ! 比熱
    real(8),parameter :: grav = 9.80665D0  ! 重力定数
    real(8),parameter :: gasr = 287.04D0   ! 気体定数
     ( 中略 )
  end module prm_phconst

• 上記定数参照型モジュールを参照等をするメインプログラムの例　（main.F90）

  program main
  !
  !  温度・高度データを標準入力して、エネルギーを標準出力する
  !
    use prm_resol  , only : imax           ! 使うものだけをあげよう
    use prm_phconst, only : cp , grav
    implicit none
  !
    real(8) :: energy     (imax)               
    real(8) :: height     (imax)               
    real(8) :: tmperature (imax)
    integer :: i
  !
    read (5,*) tmperature
    read (5,*) height
    do i=1,imax
      energy(i) = cp * tmperature(i) + grav * height(i)
    enddo
    write(6,*) energy
  end program main

　定数参照型モジュール内の定数の値は、コンパイル時に読み込まれるので、コ ンパイラが最適化を行いやすくなる。実行時に値を変更することは、もちろんで きない。

３．１．３　変数参照型モジュール

　いろいろなサブルーチンで使用する変数を、変数参照型モジュールにまとめる ことができる。

　変数参照型モジュール内の共有変数の値の設定・変更は、同じモジュール内の サブルーチンでしか行ってはいけない。外部からは値を参照するのみにする。

• 変数参照型モジュールの例　（com_tetens.F90）

  module com_tetens
    implicit none
    real(8), save :: table(25000)          ! 共有変数
  !
  contains
  !
  subroutine com_tetens__ini               ! 初期化サブルーチン
          : （table(25000)の値の設定を行う）
  end subroutine com_tetens__ini
  !
  end module com_tetens

• 上記変数参照型モジュールを参照等をするメインプログラムの例　（main.F90）

  program main
    use com_tetens,only: &
     & com_tetens__ini,  &                 ! サブルーチンcom_tetens__iniを使用。
     & table                               ! 変数tableを使用。
          :
    call com_tetens__ini                   ! tableの値の設定
          :   （以下、table(25000)の値を参照可能。変更はしない（ルール）。）
          :
  end program main

　変数参照型モジュールの共有変数は、プログラム実行時に最初に一度だけ値を 設定し、それ以後変更しないのが理想である。値の変更がある変数については、 変数参照型モジュールではなく、引数でサブルーチンに渡す方がプログラムが分 かりやすくなる場合が多いであろう。

３．１．４　パッケージ型モジュール

　パッケージ型モジュール内の共有変数や局所サブルーチンにはprivate 属性を つけ、モジュール内でのみ使用し外部から直接使用しないようにする。外部との やりとりは、初期化サブルーチンと実行サブルーチンだけを通じて行う。

　初期化サブルーチンで共有変数の初期値の設定を行う。

　実行サブルーチンはパッケージ型モジュール内に１個もしくは複数個あり、パ ッケージ型モジュールのメインの部分である。引数を通じて外部からデータを入 力し、計算を行い、引数を通じて外部に必要なデータを出力する。

• パッケージ型モジュールの例　（package1.F90）

  module package1
    use prm_resol, only : imax,jmax
    implicit none
    private                                ! private属性をdefaultに
    public :: package1__ini, package1__run ! 外部から使用可
    real(8), save :: kyouyuu(imax,jmax)    ! 共有変数、外部から使用不可
  !
  contains
  !
  subroutine package1__ini(a)              ! 初期化サブルーチン
    real(8), intent(in) :: a(imax,jmax)
          :  （kyouyuu(imax,jmax)に初期値を与える）
          :  （データの入力は、例えば、引数から・NAMELISTから・ファイルから）
          :
  end subroutine package1__ini
  !
  subroutine package1__run(b,c)            ! 実行サブルーチン
    real(8), intent(in)  :: b(imax,jmax)
    real(8), intent(out) :: c(imax,jmax)
          :
    call sub1
          :  （kyouyuu,bの値から、cの値を計算する。）
          :  （kyouyuuの値の変更も可。）
  end subroutine package1__run
  !
  subroutine sub1                          ! 局所サブルーチン
          :　　（モジュール内部でのみ使用）
  end subroutine sub1
  !
  end module package1

　パッケージ型モジュール内でのみ使用する予報変数をモジュール内の共有変数 にし、外部から隠蔽する。パッケージ型モジュール内でのみ使用するサブルーチ ンを局所サブルーチンにし、これも外部から隠蔽する。初期化サブルーチンと実 行サブルーチンのインターフェースのみを外部に公開する。

　このようにして個々のモジュールの独立性を高めることにより、プログラム全 体の構造が分かりやすくなり、多人数で大規模なプログラムの共同開発を行うこ とが容易になる。

３．１．５　モジュールの階層構造

　上の階層のモジュールが下の階層のモジュールをuseし使用する形になる。コン パイル時には、下の階層のモジュールから順にコンパイルしなければいけない。
　サブルーチンはモジュールに属するようにする。サブルーチンの属するモジュ ールを use してからでないとそのサブルーチンを使用できなくなるが、コンパ イラがコンパイル時に引数の型が一致しているかどうかチェックを行ってくれる というメリットがある。これによりデバッグが容易になる。

３．２　動的割り付け

　サブルーチン内のワーク的変数を動的にメモリに割り付けることにより、プロ グラム作成者はワーク的変数の管理から開放され、メモリを有効利用することが できる。また実行時に配列の大きさを変更できるので、解像度に依存しないプロ グラムが作成できる。

• 動的割り付けサブルーチンの例　（sub.F90）

  subroutine sub( imax, jmax, a )
    implicit none
    integer, intent(in)    :: imax
    integer, intent(in)    :: jmax
    real(8), intent(inout) :: a(imax,jmax)
  !
    real(8) :: work1(imax,jmax)            ! 自動配列
    real(8), allocatable :: work2(:,:)     ! allocate可能な配列
  !
    allocate(work2(imax,jmax))             ! メモリに割り付ける。
          :  （aの値を計算する。）
          :
    deallocate(work2)                      ! メモリを解放する。
  end subroutine sub

　上の例で、自動配列は自動的にサブルーチンの初めにメモリに割り付けられ、 サブルーチンの終わりにメモリを解放する。allocatable 配列では、allocate 文、deallocate 文で明示的に行う。

　自動配列はメモリのスタック領域を使用する場合が多く、ヒープ領域を使用す る場合が多いallocatable 配列より自動配列の方が割付を高速に行えることが多 い。しかし、使用可能なスタックのサイズに制限がある場合があり、自動配列で 使用できるメモリが制限される場合がある。（ＯＳ・コンパイラによる。）