[XL2000] ハイパーリンクが自動的に作成されないようにする方法

Microsoft Excel ワークシートに次のいずれかの文字で始まるデータを入力すると、ハイパーリンクが作成されます。

• http://
• www.
• ftp://
• mailto:
• file://
• news:
• \\

また、次の形式の電子メールアドレスを入力すると、同様に、Excel によって自動でハイパーリンクが作成されます。 Excel には、この動作を無効にする組み込みメソッドは用意されていません。この資料では Excel で自動的にハイパーリンクが作成されないようにするサンプル メソッドを 2 つ紹介します。

Excel で自動的にハイパーリンクが作成されないようにするには、次のいずれかの方法を使用します。

方法 1 : セルに入力するデータの最初にアポストロフィを挿入する

アポストロフィ (') を付けると、セルにデータを入力するときにハイパーリンクが作成されません。たとえば、Excel に次の文字列を入力すると、ハイパーリンクが自動的に作成されます。 しかし、次の文字列の場合は、ハイパーリンクが自動的に作成されることはありません。

方法 2 : アプリケーションレベルのイベント ハンドラを使用する

マイクロソフトは、この情報をプログラミング言語の使用方法の一例として提供するだけであり、市場性および特定目的への適合性を含めて、明示的にも黙示的にも、一切の保証をいたしません。この資料は、例示されているプログラミング言語やプロシージャの作成およびデバッグに使用するツールについて理解されているユーザーを対象としています。Microsoft Support 担当者は、特定のプロシージャの機能についての問い合わせにはお答えできますが、ユーザー固有の目的に合わせた機能の追加、プロシージャの作成などの内容変更は行っておりません。 次の手順では、アプリケーションレベルのイベント ハンドラを使用して、ハイパーリンクが自動的に作成されないようにする方法を説明します。

注 : この手順を実行しても、ハイパーリンクを作成する HYPERLINK ワークシート機能は引き続き利用できます。

1. 開いているブックをすべて保存して閉じ、新しいブックを作成します。
2. Visual Basic Editor を起動します (Alt + F11 を押します)。
3. [挿入] メニューで [クラス モジュール] をクリックします。
4. モジュール シートに次のコードを入力します。

   Public WithEvents NoHyperlink As Application
   
   
   Private Sub NoHyperlink_SheetSelectionChange(ByVal Sh As Object, _ 
          ByVal Target As Range)
       On Error Resume Next
       ' If the "Move selection after Enter" option is enabled.
       If Application.MoveAfterReturn Then
           ' Which direction is specified?
           Select Case Application.MoveAfterReturnDirection
               ' If the "Down" direction is specified.
               Case xlDown
                   If Target.Row = 65536 Then
                       Target.Hyperlinks.Delete
                   Else
                       Target.Offset(-1, 0).Hyperlinks.Delete
                   End If
               ' If the "Up" direction is specified.
               Case xlUp
                   If Target.Row = 1 Then
                       Target.Hyperlinks.Delete
                   Else
                       Target.Offset(1, 0).Hyperlinks.Delete
                   End If
               ' If the "Right" direction is specified.
               Case xlToRight
                   If Target.Column = 256 Then
                       Target.Hyperlinks.Delete
                   Else
                       Target.Offset(0, -1).Hyperlinks.Delete
                   End If
               ' If the "Left" direction is specified.
               Case xlToLeft
                   If Target.Column = 1 Then
                       Target.Hyperlinks.Delete
                   Else
                       Target.Offset(0, 1).Hyperlinks.Delete
                   End If
           End Select
       ' The "Move selection after Enter" option is enabled.
       Else
           Target.Hyperlinks.Delete
       End If
   End Sub
   					

5. Ctrl + R を押して、[プロジェクト] ウィンドウに切り替えます。
6. [ThisWorkbook] アイコンをダブルクリックします。
7. モジュール シートに次のコードを入力します。

   Dim objDelHyperlink As New Class1
   
   Private Sub Workbook_Open()
       Set objDelHyperlink.NoHyperlink = Application
   End Sub
   					

8. Alt + F11 キーを押して、Excel に切り替えます。
9. ファイルを保存します。
10. Alt + F11 キーを押して、Visual Basic Editor に切り替えます。
11. Workbook_Open コード内の任意の場所にカーソルを置きます。
12. F5 キーを押して Workbook_Open マクロを実行します。

ここで、「概要」に挙げたプレフィックスのいずれかを入力します。プレフィックスはハイパーリンクに自動変換されません。ただし、このマクロは Excel の現在のセッションでのみ有効です。Excel 起動時に毎回このプロシージャが実行されるようにするには、プロシージャ ファイルを Excel の起動フォルダに移動します。Excel のデフォルトの起動フォルダとして、以下のフォルダが挙げられます。

• C:\Windows\Application Data\Microsoft\Excel\Xlstart
• C:\Winnt\Profiles\User name\Application Data\Microsoft\Excel\Xlstart
• C:\Windows\Profiles\User name\Application Data\Microsoft\Excel\Xlstart
• C:\Program Files\Microsoft Office\Office\Xlstart
• フォルダの場所は、[オプション] ダイアログ ボックスの [全般] タブにある [XLSTART 代替フォルダ名] で指定します。

注 : 一部のファイルがフォルダ内に存在しない場合があります。

ハイパーリンクの作成の詳細については、[ヘルプ] メニューの [Microsoft Excel ヘルプ] をクリックします。次に、Office アシスタントまたはアンサー ウィザードにハイパーリンクの作成と入力し、[検索] をクリックして表示されるトピックを参照してください。