;*********************************************************************************************
;  MPLABアセンブラ用　Ver2(16F628A用)　
;
;
;  【 機   能 】 SE3P回転数信号処理プログラム
;		　1) 内部オシレート4MHz使用
;                   2) IGf信号のパルス数カウント処理(16bitカウンター:100～12000rpm/100rpm判定可能)
;		  3) IGf信号ノイズ除去は3回の最大パルス数(最小回転数)を使用することにより除去
;
;
;  【 履   歴 】 
;
;　【  P I C  】 PIC16F628A用
;
;  【 基   板 】 IGf信号 + 7セグ×2 + PB×2  Ver1
;
;　【 言   語 】 MPLAB用アセンブル + マクロ使用(pic_macro3.asmを使用)
;
;　【 I/Oピン 】 PIC16F62x/62xA   →　#include設定を変更することにより使用可能対象PIC
;*********************************************************************************************
; CONFIG設定(PIC16F62xA)
	LIST		p=16F628A,R=DEC		;使用PICはPIC16F628A,デフォルトは10進数
	#include	<p16F628A.inc>			;16F628Aインクルード
	#include	<C:\picmacro\pic_macro3.asm>	;マクロファイルをインクルード
	__CONFIG	_INTRC_OSC_NOCLKOUT & _WDT_OFF & _PWRTE_ON & _MCLRE_OFF & _LVP_OFF & _BODEN_OFF & _CP_OFF & _DATA_CP_ON

;変数宣言
tim0		EQU	020H	;　wait用変数1
tim1		EQU	021H	;　wait用変数2
tim2		EQU	022H	;　wait用変数3
IGfplus		EQU	023H	;  1回転あたりの点火パルス数(4気筒DOHCは通常=2パルス,REは1パルス)
rev1k_1		EQU	024H	;　設定回転数①(1000単位)
rev100_1	         EQU	025H	;　設定回転数①(100単位)
rev1k_2		EQU	026H	;　設定回転数②(1000単位)
rev100_2	         EQU	027H	;　設定回転数②(100単位)
rev1k_3		EQU	028H	;　設定回転数③(1000単位)
rev100_3	         EQU	029H	;　設定回転数③(100単位)
KINOU		EQU	02AH	;　表示機能
div1b		EQU	02BH	;　割られる数上位8bit　
div1a		EQU	02CH	;　割られる数下位8bit
div2b		EQU	02DH	;　割る数上位8bit
div2a		EQU	02EH	;　割る数下位8bit
div3b		EQU	02FH	;　答え上位8bit
div3a		EQU	030H	;　答え下位8bit
div4b		EQU	031H	;　余り上位8bit
div4a		EQU	032H	;　余り下位8bit
divl1		EQU	033H	;　内部計算用1
divl2		EQU	034H	;　内部計算用2
diverr		EQU	035H	;　割る数=0時のエラー(エラー時はdiverr=1をセット)
cal_dH		EQU	036H	;  設定回転数／100(10進数)
cal_dL		EQU	037H	;  設定回転数／100(10進数)
s_rev0_H	         EQU	038H	;　設定回転数1 の上位8bitカウント数(IGf_Hとの比較用)
s_rev1_H	         EQU	039H	;　設定回転数2 の上位8bitカウント数(　 　 〃 　　　)
s_rev2_H	         EQU	03AH	;　設定回転数3 の上位8bitカウント数(　  　〃 　　　)
s_rev3_H	         EQU	03BH	;　RED7500rpm　の上位8bitカウント数(　　　〃 　　　)
s_rev0_L	         EQU	03CH	;　設定回転数1 の下位8bitカウント数(IGf_Lとの比較用)
s_rev1_L	         EQU	03DH	;　設定回転数2 の下位8bitカウント数(　  　〃 　　　)
s_rev2_L	         EQU	03EH	;　設定回転数3 の下位8bitカウント数(　  　〃 　　　)
s_rev3_L	         EQU	03FH	;　RED7500rpm  の下位8bitカウント数(　  　〃 　　　)
IGf_H		EQU	040H	;　IGf上位8bitカウント数保持変数
IGf_L		EQU	041H	;　IGf下位8bitカウント数保持変数
E_DATA		EQU	042H	;  EEPROM書込データ一時保持変数
E_ADRS		EQU	043H	;　EEPROMデータ開始アドレス
cnt		EQU	044H	;  回転数計算時一時変数
IGfmax_H	         EQU	045H	;　3回での最大パルス数上位8bit保管変数(ノイズ信号除去用)
IGfmax_L	         EQU	046H	;　3回での最大パルス数下位8bit保管変数(ノイズ信号除去用)
max_cnt		EQU	047H	;  ノイズ処理カウント数
pluscnt		EQU	048H	;  点火パルス取得数カウンター
PBcnt		EQU	049H	;　設定表示用カウンタ
segNo		EQU	04AH	;  7セグ表示用変数
segCnt		EQU	04BH	;  7セグ表示用繰返しカウンター
SetCnt		EQU	04CH	;  7セグ表示用繰返しカウンター
segNo10		EQU	04DH	;  7セグ10の位退避変数
segNo1		EQU	04EH	;  7セグ1の位退避変数
LEDmsec		EQU	04FH	;  シフトポイントLED表示時間

prm1a		EQU	050H	;変換したい値（１バイト。変換後は壊れる）
prm3c		EQU	051H	;10進格納場所（３バイト）上位
prm3b		EQU	052H
prm3a		EQU	053H	;～下位
srlc1		EQU	054H	;カウンタ（サブルーチンで使用）
srwk1		EQU	055H	;一時余り格納場所（サブルーチンで使用）


;(47byte使用)

;固定値宣言
#DEFINE		P10		PORTA,0		;7セグ10pin
#DEFINE		DIP		PORTA,1		;7セグDIP
#DEFINE		SEGtr_1		PORTA,2		;7セグ1の位
#DEFINE		SEGtr_10	         PORTA,3		;7セグ10の位
#DEFINE		PB1		PORTA,4		;PB1
#DEFINE		PB2		PORTA,5		;PB2
#DEFINE		P1		PORTA,6		;7セグ1pin
#DEFINE		P8		PORTA,7		;7セグ8pin

#DEFINE		IGf		PORTB,0		;回転数信号(3vパルス）
#DEFINE		SP_P		PORTB,1		;車速信号(？vパルス）
#DEFINE		LED1		PORTB,2		;LED1
#DEFINE		LED2		PORTB,3		;LED2
#DEFINE		P5		PORTB,4		;7セグ5pin
#DEFINE		P4		PORTB,5		;7セグ4pin
#DEFINE		P3		PORTB,6		;7セグ3pin
#DEFINE		P2		PORTB,7		;7セグ2pin

		org		00h
		goto		start		;リセット時にはSTARTへ
		org		04h
		goto		start1		;割込時にはSTART1へ
;**************************************************************************************
; リセット時処理
start
		set_port	         TRISA,00110000b		; PORTA,4,5pin=入力
		set_port	         TRISB,00000011b		; PORTB,0pin=入力
		clrf		PORTA			; PORTAクリア
		clrf		PORTB			; PORTBクリア
		port_DIG			           	; ポートAをデジタルに設定
		mov_fl		IGfplus,1		         ; パルス数 = 1 にセット(SE3PのRE）
start1		call		LED_Allreset
		clrf		SetCnt
		clrf		PBcnt			; PBcntクリア
		clrf		pluscnt			; pluscntクリア
		clrf		segNo
		clrf		segNo10
		clrf		segNo1
		goto		read_EEPROM		; EEPROM読込み
start2		bsf		LED1
		call		tim100ms_4MHz		; 100ms待機
		bsf		LED2
		call		tim100ms_4MHz		; 100ms待機
		bsf		LED1
		bsf		LED2
		call		tim100ms_4MHz		; 100ms待機
		bcf		LED1
		bcf		LED2
		call		LED_Allreset
		goto		main

;***************************************************************************************
; メイン処理
main
		call		rev_LED
		snb		PB1
		call		setting_mode
		call		IGf_main		; PB1押下なし→パルス測定へ
		goto		main

;***************************************************************************************
;IGf信号取込＋パルス数計算処理
IGf_main
		call		rev_LED
		clrf		pluscnt			;点火パルス取得数カウンターのクリア
		clrf		IGf_H			;IGfパルスカウンタークリア
		clrf		IGf_L			;IGfパルスカウンタークリア
		snb		IGf			;IGf信号チェック(RB0)
		call		IGf_cnt0	          	;IGf信号取得した場合、パルス計算処理へ
		goto		main			;IGf信号が無い場合、mainへ
;---------------------------------------------------------------------------------------
;設定点火パルス間のカウンター(IGf_cnt*は40us)
;パルス取得～終了までのカウント
IGf_cnt0	         cje_ff		pluscnt,IGfplus,IGf_chk	; 設定パルス到達後はIGf_chkへ
		inc		pluscnt			; 取得パルス数+1
		goto		IGf_cnt11		         ; 時間合わせのためIGf_cnt11へ
IGf_cnt1	nop
		nop
		nop					; 時間合わせの修正用nop
		nop
		nop
		nop
IGf_cnt11	         incFW		IGf_H,IGf_L		; IGfカウンタ+1(16bit)
		call		wait40us_4MHz		; 40us待機(実質call～ret=27us)
		snb		IGf			; IGf信号有→IGf_cnt2、無→IGf_cnt1
		goto		IGf_cnt1
		goto		IGf_cnt2	

;パルス終了～取得までのカウント
IGf_cnt2	nop
		nop
		nop					; 時間合わせの修正用nop
		nop
		nop
		nop
		incFW		IGf_H,IGf_L		; IGfカウンタ+1(16bit)
		call		wait40us_4MHz		; 40us待機(実質call～ret=27us)
		snb		IGf			; IGf信号有→IGf_cnt0、無→繰返し
		goto		IGf_cnt0
		goto		IGf_cnt2

;---------------------------------------------------------------------------------------
;IGf信号3回取得での最大値使用処理(ノイズ信号除去処理)
;　取得IGf信号3回での最大値を正常パルス数と判断する
;   (ノイズ信号での回転数計算は最小になるはず・・・)

IGf_chk		inc		max_cnt			;収集回数カウンタ+1
		cje_fl		max_cnt,1,max1		;1回目の処理へ
		cje_fl		max_cnt,2,max2		;2回目は前回との比較処理へ
		cje_fl		max_cnt,3,maxlast		;最終回はLED点灯処理準備へ
		goto		IGf_main			; 異常の場合はメインへ戻す
		
;---------------------------------------------------------------------------------------
;最大IGf信号判定処理
max1		mov_ff		IGfmax_H,IGf_H			;1回目取得パルス数上位8bitをセット
		mov_ff		IGfmax_L,IGf_L			;1回目取得パルス数下位8bitをセット
		goto		IGf_main

max2		cja_ff		IGfmax_H,IGf_H,IGf_main		;前回上位＞今回上位 → 前回使用	
		cje_ff		IGfmax_H,IGf_H,max2_d0		;前回上位＝今回上位 → 下位bit比較へ	
		cja_ff		IGf_H,IGfmax_H,max2_d1		;前回上位＜今回上位 → 今回をセット
		goto		IGf_main
		
max2_d0		cja_ff		IGfmax_L,IGf_L,IGf_main		;前回下位＞今回下位 → 前回使用	
		mov_ff		IGfmax_L,IGf_L			;前回下位≦今回下位 → 今回をセット
		goto		IGf_main

max2_d1		mov_ff		IGfmax_H,IGf_H			;今回取得パルス数上位8bitをセット
		mov_ff		IGfmax_L,IGf_L			;今回取得パルス数下位8bitをセット
		goto		IGf_main
		
maxlast		cja_ff		IGfmax_H,IGf_H,IGf_Set		;前回上位＞今回上位 → 前回使用しLED点灯へ	
		cje_ff		IGfmax_H,IGf_H,maxlast_d0	         ;前回上位＝今回上位 → 下位bit比較へ	
		cja_ff		IGf_H,IGfmax_H,maxlast_d1	         ;前回上位＜今回上位 → 今回をセット
		goto		IGf_main

maxlast_d0	cja_ff		IGfmax_L,IGf_L,IGf_Set		;前回下位＞今回下位 → 前回使用しLED点灯へ
		mov_ff		IGfmax_L,IGf_L			;前回下位≦今回下位 → 今回をセット
		goto		IGf_Set				;LED点灯へ

maxlast_d1	mov_ff		IGfmax_H,IGf_H			;今回取得パルス数上位8bitをセット
		mov_ff		IGfmax_L,IGf_L			;今回取得パルス数下位8bitをセット
		goto		IGf_Set
		
IGf_Set		mov_ff		IGf_H,IGfmax_H			;最大パルス数上位8bitをセット
		mov_ff		IGf_L,IGfmax_L			;最大パルス数下位8bitをセット
		clrf		max_cnt				;パルス収集回数カウンタリセット
		call		cal_palus
		goto		revLED_on

;---------------------------------------------------------------------------------------
;設定回転数～-1000rpmでのLED表示
revLED_on	         cje_fl		KINOU,3,Tacho_7SEG	          	; KINOU = 3 →　回転数7セグ表示へ
		goto		rev3_chk_u			;実績と設定パルス数比較処理へ
rev3_chk_u
		cja_ff		IGf_H,s_rev3_H,revLED_1		;上位8bitが既に大きいのでLED1
		cje_ff		IGf_H,s_rev3_H,rev3_chk_d	         ;上位8bitが同じなので下位8bit_chkへ		
		cja_ff		s_rev3_H,IGf_H,rev2_chk_u	         ;上位8bitが既に小さいので次のrev_chkへ
		goto		main
rev3_chk_d
		cja_ff		IGf_L,s_rev3_L,revLED_1		;下位8bitが既に大きいのでLED1
		cje_ff		IGf_L,s_rev3_L,revLED_2
		cja_ff		s_rev3_L,IGf_L,rev2_chk_u	         ;下位8bitが小さいので次のrev_chkへ
		goto		main

rev2_chk_u
		cja_ff		IGf_H,s_rev2_H,revLED_2		;上位8bitが既に大きいのでLED2
		cje_ff		IGf_H,s_rev2_H,rev2_chk_d	         ;上位8bitが同じなので下位8bit_chkへ		
		cja_ff		s_rev2_H,IGf_H,rev1_chk_u	         ;上位8bitが既に小さいので次のrev_chkへ
		goto		main
rev2_chk_d
		cja_ff		IGf_L,s_rev2_L,revLED_2		;下位8bitが既に大きいのでLED2
		cje_ff		IGf_L,s_rev2_L,revLED_3
		cja_ff		s_rev2_L,IGf_L,rev1_chk_u	         ;下位8bitが小さいので次のrev_chkへ
		goto		main

rev1_chk_u
		cja_ff		IGf_H,s_rev1_H,revLED_3		;上位8bitが既に大きいのでLED3
		cje_ff		IGf_H,s_rev1_H,rev1_chk_d	         ;上位8bitが同じなので下位8bit_chkへ		
		cja_ff		s_rev1_H,IGf_H,rev0_chk_u	         ;上位8bitが既に小さいので次のrev_chkへ
		goto		main
rev1_chk_d
		cja_ff		IGf_L,s_rev1_L,revLED_3		;下位8bitが既に大きいのでLED3
		cje_ff		IGf_L,s_rev1_L,revLED_4
		cja_ff		s_rev1_L,IGf_L,rev0_chk_u	         ;下位8bitが小さいので次のrev_chkへ
		goto		main

rev0_chk_u
		cja_ff		IGf_H,s_rev0_H,revLED_4		;上位8bitが既に大きいのでLED4
		cje_ff		IGf_H,s_rev0_H,rev0_chk_d	         ;上位8bitが同じなので下位8bit_chkへ		
		cja_ff		s_rev0_H,IGf_H,revLED_5		;上位8bitが既に小さいので回転数オーバーへ
		goto		main
rev0_chk_d
		cja_ff		IGf_L,s_rev0_L,revLED_4		;下位8bitが既に大きいのでLED4
		cje_ff		IGf_L,s_rev0_L,revLED_5
		cja_ff		s_rev0_L,IGf_L,revLED_5		;下位8bitが小さいので次のrev_chkへ
		goto		main
;---------------------------------------------------------------------------------------
; 回転数の7セグ表示
Tacho_7SEG
		mov_ff		cal_dH,IGf_H
		mov_ff		cal_dL,IGf_L
		call		cal_palus			         ;回転数の計算			
		mov_ff		prm1a,div3a
		call		hexdec8
		mov_ff		segNo10,prm3b			; BCD変換の10の位をsegNo10
		mov_ff		segNo1,prm3a			; BCD変換の1の位をsegNo1
		call		rev_LED
		goto		main
		return

;---------------------------------------------------------------------------------------
;８ビット（１バイト）数値を１０進数３桁のＢＣＤ数値に変換する
;引き数は prm1a の１バイト
;結果は prm3c,prm3b,prm3a に得られる。
hexdec8
		movlw		srlc1				;格納場所初期値
		movwf		4h				;4h=fsr
		call		devide_hexdec			;最下位変換
		call		devide_hexdec
		call		devide_hexdec			;最上位変換
		return

devide_hexdec							;÷１０サブルーチン　（１０で除算）
		movlw		8				;８ビットくり返し
		movwf		srlc1
		clrf		srwk1
devide0_hexdec
		bcf		3h,0				;キャリフラグのクリア
		rlf		prm1a,1
		rlf		srwk1,1
		movlw		b'11110110'
		addwf		srwk1,0
		btfsc		3h,0
		movwf		srwk1
		btfsc		3h,0
		incf		prm1a,1
		decfsz		srlc1,1
		goto		devide0_hexdec
		decf		4h,1			         ;4h=fsr
		movf		srwk1,0
		movwf		0h				;余り (0h=indirect)
		return

;---------------------------------------------------------------------------------------
ShiftPoint
		call		rev_point_cal			;設定回転数での計算処理
		goto		start2
Tacho1
		call		taco_point_cal1			;1500～3500rpm計算処理
		goto		start2

;---------------------------------------------------------------------------------------
; 各設定回転数のパルス数計算(基準時間=40us:3a98)
rev_point_cal
		clrf		cal_dH
		mov_ff		cal_dL,rev100_1
		clrf		cnt
inc_rev1	         add_fl		cal_dL,10	
		inc		cnt
		cjne_ff		cnt,rev1k_1,inc_rev1	
		call		cal_palus		         ;回転数のパルス数計算			
		mov_ff		s_rev3_H,div3b		;上位8bit設定
		mov_ff		s_rev3_L,div3a		;下位8bit設定

		mov_ff		cal_dL,rev100_2
		clrf		cnt
inc_rev2	         add_fl		cal_dL,10	
		inc		cnt
		cjne_ff		cnt,rev1k_2,inc_rev2	
		call		cal_palus	          	;回転数のパルス数計算			
		mov_ff		s_rev2_H,div3b		;上位8bit設定
		mov_ff		s_rev2_L,div3a		;下位8bit設定

		mov_ff		cal_dL,rev100_3
		clrf		cnt
inc_rev3	         add_fl		cal_dL,10	
		inc		cnt
		cjne_ff		cnt,rev1k_3,inc_rev3	
		call		cal_palus	          	;回転数のパルス数計算			
		mov_ff		s_rev1_H,div3b		;上位8bit設定
		mov_ff		s_rev1_L,div3a		;下位8bit設定

		mov_fl		cal_dL,5
		clrf		cnt
inc_rev4	         add_fl		cal_dL,10	
		inc		cnt
		cjne_fl		cnt,7,inc_rev4	
		call		cal_palus	          	;回転数のパルス数計算			
		mov_ff		s_rev0_H,div3b		;上位8bit設定
		mov_ff		s_rev0_L,div3a		;下位8bit設定
		return
;---------------------------------------------------------------------------------------
; タコメータ用のパルス数計算4(基準時間=40us時)
taco_point_cal1
		mov_fl		s_rev3_H,003h		;1500回転
		mov_fl		s_rev3_L,0e8h
		mov_fl		s_rev2_H,002h		;2000回転
		mov_fl		s_rev2_L,0eeh
		mov_fl		s_rev1_H,001h		;3000回転
		mov_fl		s_rev1_L,0f4h
		mov_fl		s_rev0_H,001h		;4000回転
		mov_fl		s_rev0_L,077h
		return

;**************************************************************************************
LED_Allreset
		bcf		P1
		bcf		P2
		bcf		P3
		bcf		P4
		bcf		P5
		bcf		P8
		bcf		P10
		return
;---------------------------------------------------------------------------------------
rev_LED		cje_fl		KINOU,1,exit_rev_LED
		bsf		SEGtr_10
		bcf		SEGtr_1
		mov_ff		segNo,segNo10
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		bcf		SEGtr_10
		bsf		SEGtr_1
		mov_ff		segNo,segNo1
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
exit_rev_LED	nop
		return
;---------------------------------------------------------------------------------------
revLED_1	         cje_fl		KINOU,1,exit_revLED1
		bsf		SEGtr_10
		bcf		SEGtr_1
		mov_fl		segNo,1
		mov_ff		segNo10,segNo
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		bcf		SEGtr_10
		bsf		SEGtr_1
		mov_fl		segNo,5
		mov_ff		segNo1,segNo
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		cjne_fl		KINOU,1,main
exit_revLED1	bcf		LED1
		bcf		LED2
		mov_ff		tim0,LEDmsec
		call		LEDwait100ms_4MHz
		goto		main
		return
;---------------------------------------------------------------------------------------
revLED_2	         cje_fl		KINOU,1,exit_revLED2
		bsf		SEGtr_10
		bcf		SEGtr_1
		mov_fl		segNo,2
		mov_ff		segNo10,segNo
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		bcf		SEGtr_10
		bsf		SEGtr_1
		mov_fl		segNo,0
		mov_ff		segNo1,segNo
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		cjne_fl		KINOU,1,main
exit_revLED2	bsf		LED1
		bcf		LED2
		mov_ff		tim0,LEDmsec
		call		LEDwait100ms_4MHz
		goto		main
		return
;---------------------------------------------------------------------------------------
revLED_3	         cje_fl		KINOU,1,exit_revLED3
		bsf		SEGtr_10
		bcf		SEGtr_1
		mov_fl		segNo,3
		mov_ff		segNo10,segNo
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		bcf		SEGtr_10
		bsf		SEGtr_1
		mov_fl		segNo,0
		mov_ff		segNo1,segNo
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		cjne_fl		KINOU,1,main
exit_revLED3	bcf		LED1
		bsf		LED2
		mov_ff		tim0,LEDmsec
		call		LEDwait100ms_4MHz
		goto		main
		return
;---------------------------------------------------------------------------------------
revLED_4	         cje_fl		KINOU,1,exit_revLED4
		bsf		SEGtr_10
		bcf		SEGtr_1
		mov_fl		segNo,4
		mov_ff		segNo10,segNo
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		bcf		SEGtr_10
		bsf		SEGtr_1
		mov_fl		segNo,0
		mov_ff		segNo1,segNo
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		cjne_fl		KINOU,1,main
exit_revLED4	bsf		LED1
		bsf		LED2
		mov_ff		tim0,LEDmsec
		call		LEDwait100ms_4MHz
		goto		main
		return
;---------------------------------------------------------------------------------------
revLED_5	         cje_fl		KINOU,1,exit_revLED5
		bsf		SEGtr_10
		bcf		SEGtr_1
		mov_fl		segNo,4
		mov_ff		segNo10,segNo
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		bcf		SEGtr_10
		bsf		SEGtr_1
		mov_fl		segNo,5
		mov_ff		segNo1,segNo
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		cjne_fl		KINOU,1,main
exit_revLED5	bcf		LED1
		bcf		LED2
		mov_ff		tim0,LEDmsec
		call		LEDwait100ms_4MHz
		goto		main
		return

;***************************************************************************************
; 7セグ数値表示ルーティン

seg_on
		cje_fl		segNo,0,seg_0
		cje_fl		segNo,1,seg_1
		cje_fl		segNo,2,seg_2
		cje_fl		segNo,3,seg_3
		cje_fl		segNo,4,seg_4
		cje_fl		segNo,5,seg_5
		cje_fl		segNo,6,seg_6
		cje_fl		segNo,7,seg_7
		cje_fl		segNo,8,seg_8
		cje_fl		segNo,9,seg_9
seg_on_end	nop
		return

seg_0		bsf		P1
		bsf		P2
		bcf		P3
		bsf		P4
		bsf		P5
		bsf		P8
		bsf		P10
		goto		seg_on_end
seg_1		bcf		P1
		bcf		P2
		bcf		P3
		bcf		P4
		bcf		P5
		bsf		P8
		bsf		P10
		goto		seg_on_end
seg_2		bsf		P1
		bcf		P2
		bsf		P3
		bsf		P4
		bsf		P5
		bcf		P8
		bsf		P10
		goto		seg_on_end
seg_3		bsf		P1
		bcf		P2
		bsf		P3
		bcf		P4
		bsf		P5
		bsf		P8
		bsf		P10
		goto		seg_on_end
seg_4		bcf		P1
		bsf		P2
		bsf		P3
		bcf		P4
		bcf		P5
		bsf		P8
		bsf		P10
		goto		seg_on_end
seg_5		bsf		P1
		bsf		P2
		bsf		P3
		bcf		P4
		bsf		P5
		bsf		P8
		bcf		P10
		goto		seg_on_end
seg_6		bsf		P1
		bsf		P2
		bsf		P3
		bsf		P4
		bsf		P5
		bsf		P8
		bcf		P10
		goto		seg_on_end
seg_7		bsf		P1
		bsf		P2
		bcf		P3
		bcf		P4
		bcf		P5
		bsf		P8
		bsf		P10
		goto		seg_on_end
seg_8		bsf		P1
		bsf		P2
		bsf		P3
		bsf		P4
		bsf		P5
		bsf		P8
		bsf		P10
		goto		seg_on_end
seg_9		bsf		P1
		bsf		P2
		bsf		P3
		bcf		P4
		bsf		P5
		bsf		P8
		bsf		P10
		goto		seg_on_end

;---------------------------------------------------------------------------------------
; 16bitの割算
;　各設定回転数のパルス数の計算
cal_palus
		mov_fl		div1b,03ah		;基準時間40us( HEX(3a98) = DEC(15000) )
		mov_fl		div1a,098h
		mov_ff		div2b,cal_dH
		mov_ff		div2a,cal_dL
		call		div16			;割算実施（ 解 = div3b,a 余 = div4b,a )
		return
;16bit割算
div16
		movlw		10h			;
		movwf		divl1			;
		movf		div2a,0			;
		movwf		div4a			;
		movf		div2b,0			;
		movwf		div4b			;
di1601
		rlf		div4a,1			;1bit左シフト
		rlf		div4b,1			;1bit左シフト
		btfsc		3h,0			;Cフラグ確認
		goto		di1602			;割る数の上位ビット位置検索
		decfsz		divl1,1			;
		goto		di1601			;
		movlw		1			;
		movwf		diverr			;割る数 = 0 → エラー
		return
di1602
		clrf		div3a			;解セット用変数クリア
		clrf		div3b			;
		clrf		div4a			;ワーク用変数クリア
		clrf		div4b			;
		movlw		10h			;
		movwf		divl2			;
		movf		divl1,0			;
		subwf		divl2,1			;残ループ数
di1603
		bcf		3h,0			;Cフラグ = 0
		rlf		div1a,1			;
		rlf		div1b,1			;
		rlf		div4a,1			;
		rlf		div4b,1			;
		decfsz		divl1,1			;割られる数を初期位置までシフト
		goto		di1603			;
di1604							;現位置での減算が可否確認
		movf		div2b,0			;
		subwf		div4b,0			;
		btfss		3h,0			;
		goto		di1606			;
		movf		div4b,0			;
		subwf		div2b,0			;
		btfss		3h,0			;
		goto		di1605			;
		movf		div2a,0			;
		subwf		div4a,0			;
		btfss		3h,0			;
		goto		di1606			;
di1605
		movf		div2a,0			;
		subwf		div4a,1			;ワークから下位を引く
		btfss		3h,0			;Cフラグ = 1 →　skip
		decf		div4b,1			;上位 -1
		movf		div2b,0			;
		subwf		div4b,1			;ワークから上位を引く
		bsf		3h,0			;Cフラグ = 1
		goto		di1607			;
di1606
		bcf		3h,0			;Cフラグ = 0
di1607
		rlf		div3a,1			;Cフラグの内容を解にシフト
		rlf		div3b,1			;
		movf		divl2,1			;divl2 = 0 の確認
		btfsc		3h,2			;
		goto		di1608			;最下位まで処理したなら終了
		decf		divl2,1			;bit位置を1つ下げる（右へ）
		bcf		3h,0			;Cフラグ = 0
		rlf		div1a,1			;ワークへ1bit左シフト
		rlf		div1b,1			;
		rlf		div4a,1			;
		rlf		div4b,1			;
		goto		di1604			;
di1608
		clrf		diverr			;正常終了
		return

;**************************************************************************************
; 設定モード処理
setting_mode
		bcf		LED1			; LED1消灯
		bcf		LED2			; LED2消灯
		snb		PB1			; PB1の押下確認
		call		PB1_check	          	; PB1押下あり→押下内容確認へ
		snb		PB2			; PB2の押下確認
		call		PB2_check		         ; PB2押下あり→押下内容確認へ
		cje_fl		PBcnt,1,rev1_on		;　2 = 設定①1000回転数設定表示
		cje_fl		PBcnt,2,rev1_on		;　3 = 設定①100回転数設定表示
		cje_fl		PBcnt,3,rev2_on		;　4 = 設定②1000回転数設定表示
		cje_fl		PBcnt,4,rev2_on		;　5 = 設定②100回転数設定表示
		cje_fl		PBcnt,5,rev3_on		;　6 = 設定③1000回転数設定表示
		cje_fl		PBcnt,6,rev3_on		;　6 = 設定③100回転数設定表示
		cje_fl		PBcnt,7,KINOU_on	         ;　7 = 表示機能
		cje_fl		PBcnt,8,LEDmsec_on      	;　8 = LED表示時間100msec
		call		tim40ms_4MHz		; 20ms待機
		goto		setting_mode
;---------------------------------------------------------------------------------------
; PB1ボタン処理
PB1_check	         call		tim40ms_4MHz		; 20ms待機(チャタリング防止)
		sb		PB1			; PB1押下確認
		goto		setting_mode		; 　PB1押下無し→設定モードへ
		call		tim1sec_4MHz
		snb		PB1
		goto		write_EEPROM
		inc		PBcnt			; PBcntカウンタ数による表示内容分岐
PBcnt1		cje_fl		PBcnt,1,rev1_on		;　2 = 設定①1000回転数設定表示
		cje_fl		PBcnt,2,rev1_on		;　3 = 設定①100回転数設定表示
		cje_fl		PBcnt,3,rev2_on		;　4 = 設定②1000回転数設定表示
		cje_fl		PBcnt,4,rev2_on		;　5 = 設定②100回転数設定表示
		cje_fl		PBcnt,5,rev3_on		;　6 = 設定③1000回転数設定表示
		cje_fl		PBcnt,6,rev3_on		;　6 = 設定③100回転数設定表示
		cje_fl		PBcnt,7,KINOU_on	         ;　7 = 表示機能
		cje_fl		PBcnt,8,LEDmsec_on	         ;　8 = LED表示時間100msec
		cje_fl		PBcnt,9,clrPB		;　9 = 1に戻す処理
		return
clrPB		mov_fl		PBcnt,1			; PBcntクリア
		goto		PBcnt1
;---------------------------------------------------------------------------------------
; PB2ボタン処理
PB2_check
		call		tim40ms_4MHz		; 20ms待機(チャタリング対策)
		sb		PB2			; PB2押下確認
		goto		setting_mode		;  PB2押下無し→設定モードへ
		cje_fl		PBcnt,1,rev1k_1_up	         ;　 2 = 設定①1000回転設定を+1する処理へ
		cje_fl		PBcnt,2,rev100_1_up	;　 3 = 設定①100回転設定を+1する処理へ
		cje_fl		PBcnt,3,rev1k_2_up	         ;　 4 = 設定②1000回転設定を+1する処理へ
		cje_fl		PBcnt,4,rev100_2_up	;　 5 = 設定②100回転設定を+1する処理へ
		cje_fl		PBcnt,5,rev1k_3_up	         ;　 6 = 設定③1000回転設定を+1する処理へ
		cje_fl		PBcnt,6,rev100_3_up	;　 7 = 設定③100回転設定を+1する処理へ
		cje_fl		PBcnt,7,KINOU_up	         ;　 8 = 機能を+1する処理へ
		cje_fl		PBcnt,8,LEDmsec_up	         ;　 9 = LED表示時間msecを+1する処理へ
		return

;---------------------------------------------------------------------------------------
; 1000回転数設定①処理
rev1k_1_up
		inc		rev1k_1				; rev1k = rev1k + 1
		call		tim40ms_4MHz			; 40ms待機(チャタリング対策)
		cje_fl		rev1k_1,10,rev1k_1_clr		; if rev1k > 9 then
rev1k_1_up2	call		rev1_on				; else LCD表示処理へ
		goto		setting_mode
rev1k_1_clr	mov_fl		rev1k_1,1		            	; rev1kの初期化(=1)
		goto		rev1k_1_up2
;---------------------------------------------------------------------------------------
; 100回転数設定①処理
rev100_1_up
		inc		rev100_1			; rev100 = rev100 + 1
		call		tim40ms_4MHz		; 40ms待機(チャタリング対策)
		cje_fl		rev100_1,10,rev100_1_clr	; if rev100 > 9 then
rev100_1_up2	call		rev1_on			; else LCD表示処理へ
		goto		setting_mode
rev100_1_clr	clrf		rev100_1			; rev100の初期化(=0)
		goto		rev100_1_up2

;---------------------------------------------------------------------------------------
; 1000回転数設定②処理
rev1k_2_up
		inc		rev1k_2			; rev1k = rev1k + 1
		call		tim40ms_4MHz		; 40ms待機(チャタリング対策)
		cje_fl		rev1k_2,10,rev1k_2_clr	; if rev1k > 9 then
rev1k_2_up2	call		rev2_on			; else LCD表示処理へ
		goto		setting_mode
rev1k_2_clr	mov_fl		rev1k_2,1			; rev1kの初期化(=1)
		goto		rev1k_2_up2
;---------------------------------------------------------------------------------------
; 100回転数設定②処理
rev100_2_up
		inc		rev100_2			; rev100 = rev100 + 1
		call		tim40ms_4MHz		; 40ms待機(チャタリング対策)
		cje_fl		rev100_2,10,rev100_2_clr	; if rev100 > 9 then
rev100_2_up2	call		rev2_on			; else LCD表示処理へ
		goto		setting_mode
rev100_2_clr	clrf		rev100_2			; rev100の初期化(=0)
		goto		rev100_2_up2

;---------------------------------------------------------------------------------------
; 1000回転数設定③処理
rev1k_3_up
		inc		rev1k_3			; rev1k = rev1k + 1
		call		tim40ms_4MHz		; 40ms待機(チャタリング対策)
		cje_fl		rev1k_3,10,rev1k_3_clr	; if rev1k > 9 then
rev1k_3_up2	call		rev3_on			; else LCD表示処理へ
		goto		setting_mode
rev1k_3_clr	mov_fl		rev1k_3,2			; rev1kの初期化(=2)
		goto		rev1k_3_up2
;---------------------------------------------------------------------------------------
; 100回転数設定③処理
rev100_3_up
		inc		rev100_3			; rev100 = rev100 + 1
		call		tim40ms_4MHz		; 40ms待機(チャタリング対策)
		cje_fl		rev100_3,10,rev100_3_clr	; if rev100 > 9 then
rev100_3_up2	call		rev3_on			; else LCD表示処理へ
		goto		setting_mode
rev100_3_clr	clrf		rev100_3			; rev100の初期化(=0)
		goto		rev100_3_up2

;---------------------------------------------------------------------------------------
; 表示機能設定処理
KINOU_up
		inc		KINOU			; KINOU = KINOU + 1
		call		tim40ms_4MHz		; 40ms待機(チャタリング対策)
		cje_fl		KINOU,4,KINOU_clr		; if KINOU = 4 then 
KINOU_up2	call		KINOU_on			; else LCD表示処理へ
		goto		setting_mode
KINOU_clr	mov_fl		KINOU,1				; KINOUの初期化(=1)
		goto		KINOU_up2

;---------------------------------------------------------------------------------------
; LED表示時間msec設定処理
LEDmsec_up
		inc		LEDmsec			; LEDmsec = LEDmsec + 1
		call		tim40ms_4MHz		; 40ms待機(チャタリング対策)
		cje_fl		LEDmsec,10,LEDmsec_clr	; if LEDmsec = 10 then 
LEDmsec_up2	call		LEDmsec_on		; else LCD表示処理へ
		goto		setting_mode
LEDmsec_clr	mov_fl		LEDmsec,1			; LEDmsecの初期化(=1)
		goto		LEDmsec_up2

;***************************************************************************************
; 回転数信号①表示
rev1_on		mov_fl		segCnt,65
rev1_on2	         bsf		SEGtr_10
		bcf		SEGtr_1
		mov_ff		segNo,rev1k_1
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		bcf		SEGtr_10
		bsf		SEGtr_1
		mov_ff		segNo,rev100_1
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		djnz		segCnt,rev1_on2
		cje_fl		SetCnt,1,rev1_on3
		goto		setting_mode
rev1_on3	nop
		return
;---------------------------------------------------------------------------------------
; 回転数信号②表示
rev2_on		mov_fl		segCnt,65
rev2_on2	         bsf		SEGtr_10
		bcf		SEGtr_1
		mov_ff		segNo,rev1k_2
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		bcf		SEGtr_10
		bsf		SEGtr_1
		mov_ff		segNo,rev100_2
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		djnz		segCnt,rev2_on2
		cje_fl		SetCnt,1,rev2_on3
		goto		setting_mode
rev2_on3	nop
		return
;---------------------------------------------------------------------------------------
; 回転数信号③表示
rev3_on		mov_fl		segCnt,65
rev3_on2	         bsf		SEGtr_10
		bcf		SEGtr_1
		mov_ff		segNo,rev1k_3
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		bcf		SEGtr_10
		bsf		SEGtr_1
		mov_ff		segNo,rev100_3
		call		seg_on
		mov_fl		tim0,2
		call		wait1ms_4MHz
		djnz		segCnt,rev3_on2
		cje_fl		SetCnt,1,rev3_on3
		goto		setting_mode
rev3_on3	nop
		return
;---------------------------------------------------------------------------------------
; 機能表示
KINOU_on	         bsf		SEGtr_10
		bcf		SEGtr_1
		mov_ff		segNo,KINOU
		call		seg_on
		call		tim100ms_4MHz
		call		tim100ms_4MHz
		cje_fl		SetCnt,1,KINOU_on3
		goto		setting_mode
KINOU_on3	nop
		return
;---------------------------------------------------------------------------------------
; LED表示時間msec
LEDmsec_on	bcf		SEGtr_10
		bsf		SEGtr_1
		mov_ff		segNo,LEDmsec
		call		seg_on
		call		tim100ms_4MHz
		call		tim100ms_4MHz
		cje_fl		SetCnt,1,LEDmsec_on3
		goto		setting_mode
LEDmsec_on3	nop
		return

;--------------------------------------------------------------------------------
;【 4MHz用】10ms測定サブルーチン(測定時間=10ms×tim0)   4MHz : 1サイクル=1.0us
;--------------------------------------------------------------------------------
wait10ms_4MHz
wa20_4MHz	         mov_fl		tim1,23		;23  9.966ms
wa21_4MHz	         mov_fl		tim2,143	;143
wa22_4MHz         	djnz		tim2,wa22_4MHz
		djnz		tim1,wa21_4MHz
		djnz		tim0,wa20_4MHz
		return
;--------------------------------------------------------------------------------
;【 4MHz用】100ms測定サブルーチン(測定時間=100ms×tim0)   4MHz : 1サイクル=1.0us
;--------------------------------------------------------------------------------
LEDwait100ms_4MHz
LED20_4MHz	mov_fl		tim1,230	;230  99.66ms
LED21_4MHz	mov_fl		tim2,143	;143
LED22_4MHz	djnz		tim2,LED22_4MHz
		djnz		tim1,LED21_4MHz
		djnz		tim0,LED20_4MHz
		return

;---------------------------------------------------------------------------------
;【 4MHz用】遅延タイマー(40msecのOFF時間）
;---------------------------------------------------------------------------------
tim40ms_4MHz
		mov_fl		tim0,4   
		call		wait10ms_4MHz
		return
;---------------------------------------------------------------------------------
;【 4MHz用】遅延タイマー(100msecのOFF時間）
;---------------------------------------------------------------------------------
tim100ms_4MHz
		mov_fl		tim0,10   
		call		wait10ms_4MHz
		return
;---------------------------------------------------------------------------------
;【 4MHz用】遅延タイマー(1secのOFF時間）
;---------------------------------------------------------------------------------
tim1sec_4MHz
		mov_fl		tim0,100  
		call		wait10ms_4MHz
		return
;--------------------------------------------------------------------------------
;【 4MHz用】パルス測定タイマー(基準40usecのOFF時間) : 完成版(Call～ret=27.0us)
;--------------------------------------------------------------------------------
wait40us_4MHz
		nop
		nop
		mov_fl		tim0,2
wa30_4MHz	mov_fl		tim1,2
wa31_4MHz 	djnz		tim1,wa31_4MHz
		djnz		tim0,wa30_4MHz
		return
;--------------------------------------------------------------------------------
; 【 4MHz】1ms測定サブルーチン(測定時間=1ms×tim0)  4MHz : 1サイクル=1us
;--------------------------------------------------------------------------------
wait1ms_4MHz
wa01ms_4M	         mov_fl		tim1,6		;6   1ms
wa11ms_4M	         mov_fl		tim2,33		;33
wa12ms_4M	         djnz		tim2,wa12ms_4M
		djnz		tim1,wa11ms_4M
		djnz		tim0,wa01ms_4M
		return

;---------------------------------------------------------------------------------
;　EEPROMから各設定データの取得処理
;---------------------------------------------------------------------------------
read_EEPROM
		clrf		E_ADRS
		call		EEPROM_read		; データ取得処理
		mov_ff		rev1k_1,E_DATA		; rev1kにセット
		inc		E_ADRS			; 読込アドレス+1
		call		EEPROM_read		; データ取得処理
		mov_ff		rev100_1,E_DATA		; rev100にセット
		inc		E_ADRS			; 読込アドレス+1
		call		EEPROM_read		; データ取得処理
		mov_ff		rev1k_2,E_DATA		; rev1kにセット
		inc		E_ADRS			; 読込アドレス+1
		call		EEPROM_read		; データ取得処理
		mov_ff		rev100_2,E_DATA		; rev100にセット
		inc		E_ADRS			; 読込アドレス+1
		call		EEPROM_read		; データ取得処理
		mov_ff		rev1k_3,E_DATA		; rev1kにセット
		inc		E_ADRS			; 読込アドレス+1
		call		EEPROM_read		; データ取得処理
		mov_ff		rev100_3,E_DATA		; rev100にセット
		inc		E_ADRS			; 読込アドレス+1
		call		EEPROM_read		; データ取得処理
		mov_ff		KINOU,E_DATA		; KINOUにセット
		inc		E_ADRS			; 読込アドレス+1
		call		EEPROM_read		; データ取得処理
		mov_ff		LEDmsec,E_DATA		; LEDmsecにセット
		mov_fl		SetCnt,1
		call		rev1_on
		call		rev2_on
		call		rev3_on
		call		KINOU_on
		call		LEDmsec_on
		clrf		SetCnt
		cje_fl		KINOU,1,ShiftPoint
		cje_fl		KINOU,2,Tacho1
		goto		start2
		return
;---------------------------------------------------------------------------------
;　EEPROMデータ読出(定型処理:PIC16F62x,62xA用)
;---------------------------------------------------------------------------------
EEPROM_read
		movf		E_ADRS,0		;  w = E_ADRS
		bsf		STATUS,RP0	;  page1切替
		movwf		EEADR		;　EEADR = w
		bsf		EECON1,RD		;  読込許可
		movf		EEDATA,0		;　w = EEDATA 
		bcf		STATUS,RP0	;  page0切替
		movwf		E_DATA		;  E_DATA = w
		return
;---------------------------------------------------------------------------------
;　各設定データのEEPROMへの書込処理
;---------------------------------------------------------------------------------
write_EEPROM
		clrf		E_ADRS			; 書込アドレスリセット
		mov_ff		E_DATA,rev1k_1		; E_DATA = rev1k
		call		EEPROM_write		; EEPROMへrev100書込み
		inc		E_ADRS			; 書込アドレス+1
		mov_ff		E_DATA,rev100_1		; E_DATA = rev100
		call		EEPROM_write		; EEPROMへrev100書込み
		inc		E_ADRS			; 書込アドレス+1
		mov_ff		E_DATA,rev1k_2		; E_DATA = rev1k
		call		EEPROM_write		; EEPROMへrev100書込み
		inc		E_ADRS			; 書込アドレス+1
		mov_ff		E_DATA,rev100_2		; E_DATA = rev100
		call		EEPROM_write		; EEPROMへrev100書込み
		inc		E_ADRS			; 書込アドレス+1
		mov_ff		E_DATA,rev1k_3		; E_DATA = rev1k
		call		EEPROM_write		; EEPROMへrev100書込み
		inc		E_ADRS			; 書込アドレス+1
		mov_ff		E_DATA,rev100_3		; E_DATA = rev100
		call		EEPROM_write		; EEPROMへrev100書込み
		inc		E_ADRS			; 書込アドレス+1
		mov_ff		E_DATA,KINOU		; E_DATA = KINOU
		call		EEPROM_write		; EEPROMへgain_p書込み
		inc		E_ADRS			; 書込アドレス+1
		mov_ff		E_DATA,LEDmsec		; E_DATA = LEDmsec
		call		EEPROM_write		; EEPROMへgain_p書込み
		clrf		PBcnt			; PBcnt = 0
		mov_fl		SetCnt,1
		call		rev1_on
		call		rev2_on
		call		rev3_on
		call		KINOU_on
		call		LEDmsec_on
		clrf		SetCnt
		call		LED_Allreset
		cje_fl		KINOU,1,ShiftPoint
		cje_fl		KINOU,2,Tacho1
		goto		start2
		return
;---------------------------------------------------------------------------------
;　EEPROMデータ書込(定型処理:PIC16F62x,62xA用)
;---------------------------------------------------------------------------------
EEPROM_write
		movf		E_DATA,0		;　w = 書込データ
		bsf		STATUS,RP0		;　page1切替
		movwf		EEDATA			;　EEDATA = w
		bcf		STATUS,RP0		;  page0切替
		movf		E_ADRS,0		;　w = E_ADRS
		bsf		STATUS,RP0		;  page1切替
		movwf		EEADR			;  EEADR = w
		bsf		EECON1,WREN		;  書込許可
		movlw		55h			;　(定型処理)
		movwf		EECON2			;　　　〃
		movlw		0aah			;　　　〃
		movwf		EECON2			;　　　〃
		bsf		EECON1,WR		;　書込終了確認フラグ
eewait
		btfsc		EECON1,WR		;　書込み終了待ちloop
		goto		eewait			;　書込未終了→書込終了待ち
		bcf		EECON1,WREN		;　書込不許可
		bcf		STATUS,RP0		;　page0切替
		return
;---------------------------------------------------------------------------------
;EEPROM初期値の宣言のテスト
; シフト回転数① = 1500rpm
; シフト回転数② = 3200rpm
; シフト回転数③ = 3600rpm
; 表示機能　     = 1(1:シフトポイントインジケータ、2,3:回転数7セグ表示)
; LED表示時間　　= 7（×100ms）
	org	2100h
	de	1,5,3,2,3,6,1,7

	end