ニコニコ動画をダウンロードするには

private function nico2login(mail:String, pass:String, resultCallback:Function):void 
{
    var parameter:URLVariables = new URLVariables();
    parameter.mail = mail;
    parameter.password = pass;
    //
    var loginRequest:URLRequest = new URLRequest();
    loginRequest.url = "https://secure.nicovideo.jp/secure/login?site=niconico";
    loginRequest.method = URLRequestMethod.POST;
    loginRequest.data = parameter;
    //
    var result:URLStream = new URLStream();
    result.addEventListener(IOErrorEvent.IO_ERROR,function (e:IOErrorEvent):void 
    {
        resultCallback(false);  //  明らかな失敗
    });
    result.addEventListener(HTTPStatusEvent.HTTP_RESPONSE_STATUS,function (e:HTTPStatusEvent):void 
    {
        var reg:int = 0;
        if (    e   )
        {
            for each(var line:Object in e.responseHeaders)
            {
                if (    "x-niconico-authflag" == line.name  )
                {
                    reg = int(line.value);
                }
            }
        }
        result.close(); //  ログインが出来ればよいので、余計なページを読まないで閉じる。
        resultCallback(Boolean(reg));   //  結果
    });
    result.load(loginRequest);
}

var flvRequest:URLRequest = new URLRequest();
flvRequest.url = "http://www.nicovideo.jp/api/getflv/" + num;
//
var ldr:URLLoader = new URLLoader();
ldr.dataFormat = URLLoaderDataFormat.VARIABLES;
ldr.addEventListener(IOErrorEvent.IO_ERROR,function ():void 
{
    trace("GetFlv IO error");
});
ldr.addEventListener(Event.COMPLETE,function ():void 
{
    for(var key:String in ldr.data) 
    {
        trace(key + "=" + ldr.data[key] );
    }
});
ldr.load(flvRequest);

ldr.addEventListener(HTTPStatusEvent.HTTP_RESPONSE_STATUS,function (e:HTTPStatusEvent):void 
{   //  HTTPレスポンスヘッダ
    var r:String = "";
    if (    e   )
    {
        for each(var line:Object in e.responseHeaders)
        {
            trace(line.name + " : " + line.value);
        }
    }
});

var save:File = new File("t:/temp/" + id + ".flv");
var src:FileStream = new URLStream();
var dst:FileStream = new FileStream();
src.addEventListener(ProgressEvent.PROGRESS,function (e:ProgressEvent):void
{
    var tmp:ByteArray = new ByteArray();
    src.readBytes(tmp, 0, src.bytesAvailable);
    dst.writeBytes(tmp);
});
src.addEventListener(Event.COMPLETE,function (e:Event):void 
{
    src.close();
    dst.close();
});
dst.openAsync(save, FileMode.WRITE);
src.load(new URLRequest(url));

var infoRequest:URLRequest = new URLRequest();
infoRequest.url = "http://www.nicovideo.jp/api/getthumbinfo/" + num;
//
var ldr:URLLoader = new URLLoader();
ldr.dataFormat = URLLoaderDataFormat.TEXT;
//  情報取得で致命的なアクセスエラー
ldr.addEventListener(IOErrorEvent.IO_ERROR,function ():void 
{
    trace("GetThumbinfo IO error");
});
//  情報取得アクセス完了
ldr.addEventListener(Event.COMPLETE,function ():void 
{
    var res:XML;
    try
    {
        res = new XML(ldr.data);
    }
    catch (e:Error)
    {
        res = null;
    }
    trace(res);
});
//  情報取得アクセス開始
ldr.load(infoRequest);

var req:URLRequest = new URLRequest(url);
if (    total > 0   &&  range > 0   )
{   //  reage による ダウンロード範囲指定。（レジューム指定）
    var value:String = "bytes=" + range.toString() + "-" + total.toString();
    req.requestHeaders.push(new URLRequestHeader("Range", value));
}

//  ファイルダウンロード
private function downloadFile(url:String, total:Number, save:File,
                            reTry:int = 10, timeoutSec:int = 60):void 
{
    var src:URLStream = new URLStream();
    var dst:FileStream = new FileStream();
    //
    var range:Number = save.exists ? save.size : 0; //  途中からダウンロード
    //  タイムアウト
    var time:Timer = new Timer(1000);   //  1秒
    var timeCount:int = 0;
    time.addEventListener(TimerEvent.TIMER,function ():void 
    {
        timeCount++;
        if (    timeCount > timeoutSec  )
        {
            fsClose();
            trace("タイムアウト");
        }
    });
    //
    function fsClose():void 
    {
        src.close();
        dst.close();
        time.stop();
    }
    //  書き込むファイルストリーム
    dst.addEventListener(IOErrorEvent.IO_ERROR,function (e:IOErrorEvent):void 
    {
        trace("書き出しエラー");
        fsClose();
    });
    dst.addEventListener(Event.CLOSE,function (e:Event):void 
    {
        if (    total > range   )
        {   //  途中から再開。
            if (    reTry-- )
            {
                fsStart();
                trace("リトライ:" + reTry.toString());
            }
            else
            {
                trace("保存未完了");   //  保存未完
            }
        }
        else
        {
            trace("保存完了");  //  保存完了
        }
    });
    //  読み込むURLストリーム
    src.addEventListener(ProgressEvent.PROGRESS,function (e:ProgressEvent):void 
    {
        trace(range + " : " + e.bytesLoaded + "/" + e.bytesTotal + "(" + (e.bytesLoaded / e.bytesTotal));
        //
        timeCount = 0;  //  タイムアウトリセット
        range += src.bytesAvailable;
        //
        var tmp:ByteArray = new ByteArray();
        src.readBytes(tmp, 0, src.bytesAvailable);
        dst.writeBytes(tmp);
    });
    src.addEventListener(IOErrorEvent.IO_ERROR,function (e:IOErrorEvent):void 
    {
        trace("ダウンロードエラー");
        fsClose();
    });
    src.addEventListener(Event.COMPLETE,function (e:Event):void 
    {
        trace("ダウンロード完了");
        fsClose();
    });
    src.addEventListener(HTTPStatusEvent.HTTP_RESPONSE_STATUS,function (e:HTTPStatusEvent):void 
    {
        if (    e   )
        {
            for each(var line:Object in e.responseHeaders)
            {
                if (    String(line.name).match(/Content\-Type/i)
                    &&  String(line.value).match(/text\/plain/i)    )
                {
                    trace("flvファイルではない");
                    fsClose();
                    break;
                }
            }
        }
    });
    //  ダウンロード開始
    function fsStart():void 
    {
        if (    range < total   )
        {
            var req:URLRequest = new URLRequest(url);
            if (    total > 0   &&  range > 0   )
            {   //  reage による ダウンロード範囲指定。（レジューム指定）
                var value:String = "bytes=" + range.toString() + "-" + total.toString();
                req.requestHeaders.push(new URLRequestHeader("Range", value));
            }
            //  書き出しファイルオープン
            dst.openAsync(save, FileMode.UPDATE);
            dst.position = range;   //  レジューム開始位置
            src.load(req);
            //  タイムアウトタイマーカウント開始
            timeCount = 0;
            time.start();
        }
        else
        {
            trace("保存完了");  //  保存完了
        }
    }
    //  保存開始
    fsStart();
    trace("保存開始");
}