Excelのユーザーフォームを使って入力したい（再）

danemono_99さん

途中から失礼します。
今までの経緯を読まして頂きました。私なりに感じた点や、処理内容についてお話しさせて頂きます。
■全体の処理の流れの整理
１．製造指示用のデータはUserFormにて入力する。このUserFormは最小／最大化及び閉じるボタン付きとする。
入力項目はテキストボックスで４つ（製品名、出荷先、数量、備考に該当させる）とする。
２．UserForm1のテキストボックスに必用事項入力・・・・・その際の「製造１」と「製造２」の区分けは製品名の頭に”１－”と”２－”を付けることとする。
３．データ入力後、「入力」ボタンクリックで以下のシートにそれぞれ転記し、そのあとテキストボックスをクリアする。
・Sheet「マスター」・・・・・・・・・入力された全てのデータを累積保管する。（最下行に追加していく）
・Sheet「第１製造」・・・・・・・・製品名が”１－”で始まる製品のデータを累積保管する。（同 上）
・Sheet「第２製造」・・・・・・・・製品名が”２－”で始まる製品のデータを累積保管する。（同 上）
＊質問では・常にSheet「第１製造」、「第２製造」をクリアし、全データを再度フィルーにて振り分けを行うようですが、どうせなら常に１件毎に追加処理をかけた方が処理が速いのでは（全データ件数が増えた場合）と思い↑の構想にしました。
ですのでコマンドボタンは「入力」ボタンのみで後は削除。そのボタンのイベントもいらない。
↓をUserForm1のモジュールにコピペ。

Option Explicit
Dim lngRow As Long
Dim i As Integer
Dim Ws1 As Worksheet, Ws2 As Worksheet
Dim lngRow1 As Long, lngRow2 As Long
Dim r As Integer
'''入力
Private Sub CommandButton1_Click()''入力ボタンクリック

Call fInput ''マスターへの転記を実行
Call Furiwake''それぞれへ転記実行（新規部分です。）
Call fOutput ''クリア処理実行

End Sub


Private Sub fInput() ''マスターシートへの転記
Dim Ws As Worksheet
Set Ws = Sheets("マスター")
With Ws
lngRow = .Range("A" & Rows.Count).End(xlUp).Row + 1 ''最下行取得
For i = 1 To 4
.Cells(lngRow, i) = CStr(Me.Controls("TextBox" & i).Value)
Next
End With
End Sub

'''
Private Sub fOutput() ''クリア処理
For i = 1 To 4
Me.Controls("TextBox" & i).Value = ""
Next
End Sub

Private Sub Furiwake() ''製造毎振り分け

Set Ws1 = Sheets("第1製造"): Set Ws2 = Sheets("第2製造")

lngRow1 = Ws1.Range("A" & Rows.Count).End(xlUp).Row + 1 ''第１製造最下行取得
lngRow2 = Ws2.Range("A" & Rows.Count).End(xlUp).Row + 1 ''第２製造最下行取得


For r = 1 To 4

Select Case Mid(Me.TextBox1.Value, 1, 1)''商品名の頭１文字で条件分岐
Case "1"
Ws1.Cells(lngRow1, r).Value = CStr(Me.Controls("TextBox" & r).Value)
Case "2"
Ws2.Cells(lngRow2, r).Value = CStr(Me.Controls("TextBox" & r).Value)
End Select
Next r

Set Ws1 = Nothing
Set Ws2 = Nothing

End Sub

■最小／最大化ボタンの件（参考サイト：http://www.serpress.co.jp/excel/vba047.html）
１．以下のコードを「標準モジュール」にコピペ。
Option Explicit
Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
(ByVal lpClassName As String, _
ByVal lpWindowName As String) As Long
Public Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" _
(ByVal hWnd As Long, _
ByVal nIndex As Long) As Long
Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" _
(ByVal hWnd As Long, _
ByVal nIndex As Long, _
ByVal dwNewLong As Long) As Long
Public Declare Function DrawMenuBar Lib "user32" _
(ByVal hWnd As Long) As Long

Public Const GWL_STYLE = (-16) 'ウィンドウスタイルを取得
Public Const WS_THICKFRAME = &H40000 'ウィンドウのサイズ変更
Public Const WS_MINIMIZEBOX = &H20000 '最小化ボタン
Public Const WS_MAXIMIZEBOX = &H10000 '最大化ボタン

２．以下を「ThisWorkbook」－「Open」イベントにコピペ（今あるUserFoem1.Showは削除）
'***** ボタンを表示する処理 *****
Dim fRet As Long
Dim hWnd As Long
Dim fStyle As Long

UserForm1.Show vbModeless 'ユーザーフォームを表示する

hWnd = FindWindow("ThunderDFrame", "UserForm1") 'ユーザーフォームのハンドルを取得する
fStyle = GetWindowLong(hWnd, GWL_STYLE) 'ウィンドウに関する情報を取得する
fStyle = (fStyle Or WS_THICKFRAME Or WS_MAXIMIZEBOX Or WS_MINIMIZEBOX) 'Min,Maxメニューボタンを付加する
fRet = SetWindowLong(hWnd, GWL_STYLE, fStyle) 'ユーザーフォームに追加したボタンを設定する
fRet = DrawMenuBar(hWnd) 'ユーザーフォームのメニューバー外枠を再描画する