Jです。おはこんばんちわ。

※今回は完全にチラ裏日記

たまにプログラムすると楽しくて時間を忘れてしまう。

今日はどこからかゲッツしたmp4ファイルの音声を差し替えるバッチを作ってみた。
（歌ってみた用にひっそりと作成）

必要なファイルは以下の通り


１．音声圧縮（AAC-LC）用エンコーダ
Nero Digital Audio Reference MPEG-4 & 3GPP Audio Encoder
→必要なのは"neroAacEnc.exe"

２．mp4結合ソフト
MP4Box
→必要なのは"MP4Box.exe"

３．以下の内容を記述したバッチファイル(.bat)
〜〜〜〜ここから〜〜〜〜
@echo off
setlocal

if not "%3" == "" goto error1

if "%~x1" == ".mp4" (
  set video=%1
) else (
  if "%~x1" == ".wav" set audio=%1
)

if "%~x2" == ".mp4" (
  set video=%2
) else (
  if "%~x2" == ".wav" set audio=%2
)

if %video% == "" goto error2
if %audio% == "" goto error2

set enc_audio=%audio:wav=m4a%

echo ***** Audioビットレート選択 *****
echo [1] : 32kbps
echo [2] : 64kbps
echo [3] : 96kbps
echo ****************************

set /p NUM="希望のビットレートの番号を選択してね 1-3 >"

if "%NUM%"=="1" (
  set bitrate=32000
  echo 32kbpsでエンコするよっ
)
if "%NUM%"=="2" (
  set bitrate=64000
  echo 64kbpsでエンコするよっ
)
if "%NUM%"=="3" (
  set bitrate=96000
  echo 96kbpsでエンコするよっ
)
echo.

@echo on
"%~dp0neroAacEnc.exe" -br %bitrate% -lc -if %audio% -of %enc_audio%
@echo off
echo 音声のエンコが終わったよ。続いて映像とくっつけるよ。
echo.

@echo on
"%~dp0MP4Box.exe" -add %video%#video -add %enc_audio%#audio -new "%~dp0out.mp4"
@echo off
goto end

:error1
echo 入力ファイルは2つ選択してね。
goto end

:error2
echo wavとmp4を1個ずつ選択してね。
goto end

:end
echo 処理が終わりました。
pause
〜〜〜〜ここまで〜〜〜〜

4.映像元mp4

5.差し替え用音声ファイル(wavであること。mp3はだめよ)


上記5つのファイルを同じフォルダ内におきまして、
エクスプローラから4、5のファイルを同時選択してバッチファイルにドラッグするのだ。

するとコマンドプロンプトが開き、ビットレート選択を聞かれるので、
合成後のファイルが40MBをオーバしないレートを選ぶ。
10分以下程度なら96kbpsでいいはず。

あとは全自動〜


うまくいけば、WAVファイルの拡張子がm4a（AAC-LC圧縮）になってるものと、
音声が差し替えられたout.mp4が出来上がっているはず。


既存の映像を使う場合には、作者様への感謝の気持ちを忘れてはいけません。



あぁ〜空が明るくなっているのをみると、賢者タイムがやってくる。


まぁたまにはこんな日もいいかな。